listbox con elementi separati

[GunraY]

ciao a tutti,
è possibile separare gli item di un listbox con una riga? ho provato ad aprire le varie skin, ma riesco a fare apparire le righe solo se l'item è selezionato...

[negatyve]

Intendi il listbox del flashmx?

[GunraY]

si nega, proprio quello

[negatyve]

• crea un movieclip vuoto in libreria
• assegnagli un linkage qualsiasi
• scrivici dentro:

#initclip 3

//  This is for adjusting the size of the highlight and its associated hit area
FSelectableItemClass.prototype.setSize = function(width, height)
{
	var LOWEST_DEPTH = -16384; // A constant (!) for the lowest authortime depth
	this.width = width;
	this.layoutContent(width); // EXTEND this for alternate content.
	
	this.attachMovie("FHighlightSymbol", "highlight_mc", LOWEST_DEPTH);
	this.highlight_mc._x=0.5;
	this.highlight_mc._width = width-0.5;
	this.highlight_mc._height = height;
	this.highlight_mc.controller = this;

	this.highlight_mc._alpha = 0;
	this.highlight_mc.trackAsMenu = true;

	this.highlight_mc.onPress = function()
	{
		if (this.controller.enable) {
			this.controller.controller.clickHandler(this.controller.itemNum);
			
		}
	}
	this.highlight_mc.onDragOver = function()
	{
		if (this.controller.controller.focused) {
			this.onPress();
		}
	}
	this.highlight_mc.useHandCursor = false;
	this.highlight_mc.trackAsMenu = true;
	var mc = this.createEmptyMovieClip("line_separator", 10000);
	mc._y = height;
	mc.lineStyle(1, 0x000000, 100);
	mc.lineTo(width, 0);
}

#endinitclip

[GunraY]

premesso che sei un dio
mi spiegheresti dov'è che, in quello script, i listbox presenti nel filmato "capiscono" che devono attaccarsi qusto nuovo mc-separatore?

[negatyve]

Ho aggiunto questo pezzo alla fine del metodo:

var mc = this.createEmptyMovieClip("line_separator", 10000);
mc._y = height;
mc.lineStyle(1, 0x000000, 100);
mc.lineTo(width, 0);

In questo modo, ho sovrascritto un metodo della Classe FSelectableItemClass che serve a creare il singolo item della lista, creando il pulsante e la label. Alla fine di questo metodo, ho aggiunto la creazione di un movieclip nel quale viene disegnata una linea. Tutto qui.. :)

[GunraY]

dovrò impararli sti cacchi di classe e oggetti prima o poi!
Grazie Nega

[negatyve]

E di che.. :)