mouse che muove mc

[gigi_bonafede]

Ciao a tutti
vorrei creare un mc ( un cerchio ) che si sposti quando viene sfiorato dal mouse e vada nelle direzione opposta: Esempio se tocco il cerchio a dx vorrei che il mc mi si spostasse a sx, se lo tocco dall'alto vorrei che il mc si spostasse in basso e così di seguito: c'e' qualcuno che può aiutarmi? Ciao!

[l_lennynero_l]

si spostasse di quanto? voglio dire vuoi che prosegua o si fermi e torni nel punto dove stava allontanado il mouse?

[gigi_bonafede]

ciao l_lennynero_l
vorrei che mi si spostasse di un poco, pero' sarebbe bello anche che tornasse nella posizione di partenza; è possibile?

[l_lennynero_l]

ho uno script che fa per te...
usi Flash Player 7 o inferiore?

[gigi_bonafede]

ho flash5 ma anche flashMX :quote:

[l_lennynero_l]

guarda un po' se questo va bene:

MovieClip.prototype.myGetNextHighestDepth = function() {
	var hd = -1;
	for (var x in this) {
		if (typeof (this[x]) == "movieclip") {
			hd = (this[x].getDepth()>hd) ? this[x].getDepth() : hd;
		}
	}
	return hd+1;
};
MovieClip.prototype.startMagnetic = function(m) {
	var homex, homey, magnet, x0, x1, y0, y1, distancex, distancey, distance, powerx, powery, forcex, forcey;
	homex = this._x;
	homey = this._y;
	magnet = m;
	forcex=0;
	forcey=0;
	this.createEmptyMovieClip("magnetic", this.myGetNextHighestDepth());
	this.magnetic.p = this;
	this.magnetic.onEnterFrame = function() {
		x0 = this.p._x;
		y0 = this.p._y;
		x1 = this.p._parent._xmouse;
		y1 = this.p._parent._ymouse;
		distancex = x1-x0;
		distancey = y1-y0;
		
		distance = Math.sqrt((distancex*distancex)+(distancey*distancey));
		powerx = this.p._x-(((distancex/distance)*magnet)/distance);
		powery = this.p._y-(((distancey/distance)*magnet)/distance);
		forcex = (forcex+((homex-x0)/2))/1.5;
		forcey = (forcey+((homey-y0)/2))/1.5;
		this.p._x = powerx+forcex;
		this.p._y = powery+forcey;
	};
};
MovieClip.prototype.stopMagnetic = function() {
	this.magnetic.removeMovieClip();
};

un esempio:

m=100; //prova a regolare m
nomeClip.startMagnetic(m);

per rimuovere l'effetto:

nomeClip.stopMagnetic();

[gigi_bonafede]

ciao l_lennynero_l
scusami mi potresti dire dove dovrei inserire queste actions perchè ho provato ad indicarle sia in un frame che sul mc ma mi da errore in entrambi i casi tu le hai provate? E poi, devo traformare il mc (cerchio)in un bottone? Ciao

[l_lennynero_l]

scrivi le tre prototype nel primo frame del tuo filmato

quando incolli attento a questa riga:

distance = Math.sqrt((distancex*distancex)+distancey*distancey));

deve stare tutto sulla stessa riga senza andare a capo.


Crea il tuo cerchio trasformalo in simbolo (movieclip) e fai in modo che il centro del clip sia anche il centro del cerchio, e dagli un nome, es: cerchio.

poi nel frame che contiene il cerchio scrivi:

m=100; //prova a regolare m
cerchio.startMagnetic(m);

dovresti ottenere un effetto magnetico con il cerchio che si allontana se il mouse si avvicina.

[Zippo]

scusate se m'intrometto...lennynero, ho visto che sei molto bravo a creare effetti particolari (quello del testo è spettacolare) usando i prototype, mi piacerebbe capire meglio cosa sono e come usarli, potresti indicarmi un link dove vengono spiegati?

Grazie

[gigi_bonafede]

Grazie l_lennynero_l
:quote: :quote: :quote: :quote: :quote: ci sono riuscitoooooo . Ti chiedo un'ultima cosa: che variazione bisogna apportare per fare in modo che il cerchio una volta toccato si sposti senza ritornare al punto di partenza?