[VB 6] sfoglia tra le cartelle

[ale500]

salve a tutti, ho provato a cercare sia nel mio pc che nel forum ma non ho trovato niente, eppure un po di tempo fa ero stato proprio io a postare l'esempio...cmq mi servirebbe sapere come si fa a richiamare quella schermata di windows che ti permette di fare lo sfoglia tra le cartelle....

non so se mi sono fatto capire, l'utente sfoglia tra le cartelle fino a trovare la cartella che gli serve, la seleziona e clicca su ok e da programma devo sapere il percorso della cartella che l'utente ha selezionato...

fatemi sapere, purtroppo non trovo più l'esempio, grazie ciao

confido in voi

[Pestilence]

Se ti interessa ricercare un determinato file devi usare una commondialog con comando

Commondialog.filter = "File di Testo (*.txt) |*.txt| Documenti (*.doc) |*.doc"
Commondialog.showopen

se devi aprire solo una cartella usa i commoncontrol e metti un tree e da li cerchi la cartella per il resto non so come aiutarti sinceramente non mi è mai servito di selezionare una cartella bensì un determinato file

[xegallo]

penso intendi questo

Private Type BROWSEINFO
     hOwner As Long
     pidlRoot As Long
     pszDisplayName As String
     lpszTitle As String
     ulFlags As Long
     lpfn As Long
     lParam As Long
     iImage As Long
End Type

Private Const BIF_RETURNONLYFSDIRS = &H1
Private Declare Function SHBrowseForFolder Lib "shell32.dll" Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32.dll" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal pv As Long)

Public Function SfogliaCartelle(ByVal Handle As Long) As String
     Dim BInfo As BROWSEINFO
     Dim CartellaScelta As Long
     Dim PercorsoAllocato As Long
     Dim PercorsoScelto As String
     BInfo.hOwner = Handle
     BInfo.lpszTitle = "Scegli una cartella:"
     BInfo.ulFlags = BIF_RETURNONLYFSDIRS
     PercorsoAllocato = SHBrowseForFolder(BInfo)
     PercorsoScelto = Space$(512)
     CartellaScelta = SHGetPathFromIDList(PercorsoAllocato, PercorsoScelto)
     If CartellaScelta Then
          SfogliaCartelle = Left$(PercorsoScelto, InStr(PercorsoScelto, Chr$(0)) - 1)
          CoTaskMemFree PercorsoAllocato
     Else
          SfogliaCartelle = ""
     End If
End Function

per richiamarla

variabilestringa = SfogliaCartelle(nomeform.hWnd)

[ale500]

perfetto, era proprio quella che cercavo....grazie...

ma esisiste una speci di raccolta con tutte le funzioni pubbliche messe a disposizione dal sistema da richiamare?????


grazie