File txt

[francy_eb]

Ciao Ragazzi,
il mio problema è il seguente, ho un file di txt strutturato nel seguente modo:
------------------
categoria1>SottoCategoria1>>Prodotto1
categoria1>SottoCategoria1>>Prodotto2
categoria1>SottoCategoria1>>Prodotto3
categoria1>SottoCategoria1>>Prodotto4
categoria1>SottoCategoria1>>Prodotto5
Categoria2>SottoCategoria2>>Prodotto1
Categoria2>SottoCategoria2>>Prodotto2
Categoria2>SottoCategoria2>>Prodotto3
Categoria2>SottoCategoria2>>Prodotto4
Categoria2>SottoCategoria2>>Prodotto5
Categoria3>SottoCategoria3>>Prodotto1
Categoria3>SottoCategoria3>>Prodotto2
Categoria3>SottoCategoria3>>Prodotto3
Categoria3>SottoCategoria3>>Prodotto4
Categoria3>SottoCategoria3>>Prodotto5
------------------
Il dovrei leggere la categoria che è quella che risiede prima del carattere ">" e stamparla e far si che non vi siano duplicati.
Come posso fare?
Grazie

[fdaguanno]

Et voilà...

<%
	Option Explicit

	const NomeFile = "Categorie.txt"

	dim FileSystemObject
	dim File
	dim path
	dim appo_Stringa
	dim Stringa, OLD_Stringa
	dim Posizione

	OLD_Stringa = ""
	path = Server.MapPath(NomeFile)

	Set FileSystemObject = CreateObject("Scripting.FileSystemObject")

	if FileSystemObject.FileExists(path) then
		Set File = FileSystemObject.OpenTextFile(path,1)

		Do While File.AtEndOfStream <> True
		    appo_Stringa = File.ReadLine
		    Posizione = InStr(1,appo_Stringa,">") - 1
		    Stringa = left(appo_Stringa,Posizione)
		    if OLD_Stringa <> Stringa then
				Response.Write Stringa & "
"
				OLD_Stringa = Stringa
			end if
		Loop

		File.Close
		set File = Nothing
	end if

	set FileSystemObject = Nothing	
%>