calendario asp

[tse]

ciao ragazzi..
conoscete qualche bel calendario fatto bene in asp...con grafica molto carina??
ho cercato ma molta roba carina è a pagamento....
ho visto il calendario di xoops e mi piacerebbe qualcosa del genere pero in asp..
io sto girando girando...
ma senza particolari risultati....
se conoscete battete un colpo.
CIAO.

[ZeroCool981]

Ti posto un calendario che ho fatto io, la grafica poi la puoi modificare a seconda delle tue esigenze.
C'e' del codice in più perchè a me serviva per una specie di agenda, cmq basta che togli il link a ogni giorno e il controllo che esistano delle prenotazioni, ed hai un calendario perfetto.
Gestisce e visualizza perfettamente i giorni del mese a seconda dell'anno.



<%
Session.LCID = 1040

' se non passiamo nessun valore parte dalla data odierna
If Request("data") ="" then
data = Date()
else
data = CDate(Request("data"))
end if

mese = Month(data)
anno = Year(data)

' conta il numero di giorni in un mese
function giornidelmese(mese, anno)
DataInizio = CDate("01/" & mese & "/" & anno)
DataFine = DateAdd("m", 1, DataInizio)
giornidelmese = DateDiff("d", DataInizio, DataFine)
end function
%>
<div align="center">
<%
response.write("Oggi &egrave; il giorno: "& date() &"
")
%>
<table border="1" cellpadding="0" cellspacing="0" bordercolor=black>
<tr>
<td align="center"><a href="calendario.asp?data=<%=DateAdd("m", -1, data)%>" style="color: black; text-decoration: none">&lt;</td>
<td colspan="5" align="center"><%=MonthName(Month(data)) & " " & Year(data)%></td>
<td align="center"><a href="calendario.asp?data=<%=DateAdd("m", 1, data)%>" style="color: black; text-decoration: none">&gt;</td>
</tr>
<tr bgcolor="#C0C0C0">
<td width="30" align="center">Dom</td>
<td width="30" align="center">Lun</td>
<td width="30" align="center">Mar</td>
<td width="30" align="center">Mer</td>
<td width="30" align="center">Gio</td>
<td width="30" align="center">Ven</td>
<td width="30" align="center">Sab</td>
</tr>
<%
DataInizio = CDate("01/" & mese & "/" & anno)

' saltiamo primi giorni della settimana
for i = 1 to WeekDay(DataInizio)-1
if i = 1 then Response.Write "<tr>"
Response.write "<td bgcolor=white></td>"
next

'mostriamo il calendario
for i = 1 to giornidelmese(mese,anno)
data = Cdate(( i & "/" & mese & "/" & anno))
if WeekDay(data) = 1 then Response.Write "<tr>"

'cerchiamo se esistono delle prenotazioni associati al giorno
strsql="SELECT COUNT(*) AS num_rec FROM prenotazioni WHERE prenotazioni.dataprenotazione = # "& data &" # "
rsusers.open strsql, adocon
contarec=rsusers.fields("num_rec")
rsusers.close

'se abbiamo trovato un record
if contarec > 0 then
Response.write("<td align=""center"" ")

strsql = "SELECT * FROM prenotazioni WHERE prenotazioni.dataprenotazione = # "& data &" # "
rsusers.open strsql, adocon
tipologia = rsusers("tipologia")
rsusers.close

if tipologia = "tavolo" then
Response.Write("bgcolor=""blue"">")
elseif tipologia = "sala" then
Response.Write("bgcolor=""orange"">")
end if
else
Response.Write("<td align=""center"">")
end if

Response.write("" & i & "")
Response.write("</td>")
if WeekDay(data) = 7 then Response.Write "</tr>"
next

' saltiamo primi giorni della settimana
for j = WeekDay(Data)+1 to 7
Response.write "<td bgcolor=white></td>"
if j mod 7 = 0 then Response.Write "</tr>" : exit for
next
%>
</table>

[tse]

ehm ti ringrazio.....
ma mi son spiegato male...
ho bisogno di avere un agenda piu che un calendario..
ho la necessita di inserire spettacoli in calendario con la possibilità di poter inserire il manifesto in jpeg dello spettacolo.....
e poi aggiungere inoltre un controllo sulla data in modo che allo scattare del lunedi pubblichi in home lo spettacolo della nuova settimana.....
è un attimino piu complesso...
poi per giunta mi muovo molto con php-mysql...ed ho un server winzoz sotto mano....e quindi mi ci devo adattare....purtroppo....

....