Aiuto Urgentissimo!

[xlration]

Il mio problema è il seguente.
Sto realizzato un sito flash con sfondi diversi a seconda dell'area selezionata nell'homepage (anchessa con uno sfondo).

E' un pò difficile da spiegare, quindi farò un esempio:

Diciamo che ho 3 sfondi, uno giallo, uno verde ed uno bianco.
Ovviamente, su ogni sfondo, ci sono i link per gli altri due (ad esempio, sul giallo ci sarà il link per il verde e per il bianco).
Il mio problema è quello di passare da uno sfondo all'altro (cliccando sul link apposito), con una piccola animazione.
Vorrei che, ad esempio, se sono sul fondo giallo, ma voglio passare allo sfondo verde, cliccando sul pulsante verde lo sfondo giallo sparisca con una piccola animazione (alfa0%), e compaia lo sfondo verde.
Per fare questo, ho posizionato i tre sfondi, ognuno con un'animazione di apertura e chiusura, in diverse posizioni della timeline.
Mi basta quindi assengnare un <goto> al pulsante, per far apparire il nuovo sfondo.
Ma io vorrei che ci fosse un'animazione che fa sparire il primo sfondo e comprarire il nuovo.
Quindi ho dato ad ogni sfondo 50 fotogrammi, ho messo uno stop al 40, e creato l'interpolazione da alfa 100% a alfa0% tra il 41 e il 50.
In questo modo il fondo scompare.
Al fotogramma 50 poi ho inserito un semplice <goto> per dirgli di andare al fotogramma della timeline contenente il nuovo sfondo.
Se avessi due soli sfondi avrei risolto così, ma visto che ne ho 4, devo poter inserire nel fotogramma 50, 3 <goto> diversi(uno a seconda della sezione), ma il mio problema è come far capire a flash che, se clicco sul pulsante a, deve prendere il <goto>a, se clicco su b, il <goto>b, e così via.
Un mio amico mi ha detto che si dovrebbe poter fare con gli IF.
Io purtroppo non sono esperto e non conosco questa funzione.
Potete aiutarmi?
E' un pò contorto, ma meglio di così non riesco a spiegarlo.
Grazie a tutti, davvero.

XL.

[andr3a]

• leggi il regolamento prima di postare, il titolo di questa discussione non e' utile a nessuno
• esempio on-line ... se e' questo che volevi fare ...
• il codice ...

// GESTORE FADE-IN / FADE-OUT
var backGoundManager = new Object();
backGoundManager.path = this; // path dove risiedono i movies
backGoundManager.movies = Array( "red", "green", "blue" ); // nome istanza movies
backGoundManager.reset = function() {
	var movies = this.movies;
	for( var a = 0; a < movies.length; a++ ) {
		this.path[movies[a]]._alpha = 0;
	}
}
backGoundManager.fadeIn = function( who ) {
	this.__lastMovie = who;
	this.path[who].onEnterFrame = function() {
		if( this._alpha >= 100 ) {
			this._alpha = 100;
			delete this.onEnterFrame;
		}
		else {
			this._alpha += 2;
		}
	}
}
backGoundManager.fadeOut = function( nextMovie ) {
	if( nextMovie != this.__lastMovie ) {
		var path = this;
		var lastMovie = this.__lastMovie;
		this.path[lastMovie].onEnterFrame = function() {
			if( this._alpha <= 0 ) {
				this._alpha = 0;
				path.fadeIn( nextMovie );
				delete this.onEnterFrame;
			}
			else {
				this._alpha -= 2;
			}
		}
	}
}
backGoundManager.reset();




// FACCIO PARTIRE IL PRIMO MOVIE ( a caso )
var fRM = backGoundManager.movies[ Math.round( Math.random() * 2 ) ];
backGoundManager.fadeIn( fRM );



// AZIONI A PULSANTE
red_btn.onPress = function() {
	backGoundManager.fadeOut( "red" );
}
green_btn.onPress = function() {
	backGoundManager.fadeOut( "green" );
}
blue_btn.onPress = function() {
	backGoundManager.fadeOut( "blue" );
}

[xlration]

Mi scuso per il titolo poco rispettoso del regolamento, e ti ringrazio per il tuo aiuto.

Io però dovrei fare una cosa un pò diversa.

Ho 3 immagini di background (una per sezione), ognuna in posizioni diverse della timeline.
Ognuna delle immagini ha un'animazione di apertura ed una di chiusura (praticamente da alfa0% a 100% nei primi 10 fotogrammi e 100% a 0% negli ultimi 10).
Su ogni immagine ci sono i pulsanti che ti rimandano ad un'altra (in un altro punto della timeline).
Io vorrei far si che cliccando su un pulsante, la timeline si sposti sul relativo fotogramma con l'animazione di chiusura dell'immagine e, all fine di questa la timeline si spostasse al fotogramma con la nuova immagine.
Mi sarebbe bastato mettere un <goto>+il (numero del fotogramma dell'immagine che voglio far partire), alla fine dell'animazione di chiusura, ma
i background però sono 4

Mi servirebbe uno script che mi permetta di inserire sull'ultimo fotogramma dell'animazione di chiusura di ogni immagine i tre <goto> con le posizioni sulla timeline delle varie immagini.
A seconda del pulsate che ho premuto però, deve partire il <goto> corrispondente. :master:

[andr3a]

image1_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE1";
}
image2_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE2";
}
image3_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE3";
}

poi chiami i frames di apertura di ogni immagine

IMAGE1, IMAGE2 e IMAGE3

e alla chiusura di ogni immagine metti sul frame delle actions

this.gotoAndPlay( _root.nextImage );

[xlration]

Grazie davvero per l'aiuto che mi stai dando
Un utlima cosa:

image1_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE1";
}
image2_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE2";
}
image3_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE3";
}

questi script devo inserirli in ogni pulsante?

[andr3a]

Originariamente inviato da xlration
Grazie davvero per l'aiuto che mi stai dando
Un utlima cosa:

image1_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE1";
}
image2_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE2";
}
image3_btn.onPress = function() {
_root.gotoAndPlay( 10 ); // o il frame di chiusura
_root.nextImage = "IMAGE3";
}

questi script devo inserirli in ogni pulsante?

no, su un frame dedicato per le Actions ... ma visto che me lo domandi, dubito che ci sia ... beh, creane uno e mettilo in cima agli altri ... dovrebbe bastare una volta sola ma per stare sicuro mettilo su ogni "mezza animazione" di ogni immagine ( ovvero a fine "entrata" di ogni movie )

image1_btn, image2_btn e image3_btn sono i nomi di istanza dei bottoni

[xlration]

Perfetto!!
Non funzionava perché non avevo aggiunto _root
Grazie davvero