caricamento immagine con LoadVars e resize con preload

[teohell]

Ciao a tutti!
apro un nuovo th perche' in effetti l'argomento esula dal subj del th che avevo aperto inizialmente (questo)

in pratica il problema e' che carico un'img utilizzando loadvars (si carica correttamente) dopodiche' vorrei ridimensionare il clip che la contiene (clip vuoto su _root con nome istanza "clip") utilizzando un preload... pero' non riesco a capire dove sbaglio, perche' non funziona!
l'immagine viene caricata, ma non viene ridimensionata... e quello che ancora mi risulta piu' strano in assoluto e' che non viene nemmeno nascosta utilizzando la proprieta' _visible=false!!!!

ecco il codice per chi vorra' darmi una mano:

//preload
function preload() {
	clip.onEnterFrame = function(){
   		if (clip.getBytesLoaded()>1024 && clip.getBytesLoaded() == clip.getBytesTotal())) {
		//setto dimensioni
		clip._height = 192;
		clip._width = 256;
		clip._visible = true;
		//cancello enterframe
    	        delete clip.onEnterFrame;
   		}
	}
}

//definisco l'oggetto
myVars = new LoadVars();
	 
//caricamento immagine
myVars.onLoad  = function (success) {
     if (success) {
		 clip.loadMovie(myVars.immagine);
		 clip._visible = false;
		 preload();
    } else {
        trace ("Errore");
    }
}

//chiamata metodo load all'oggetto loadvars
myVars.load("product_info_2.php?products_id="+_root.products_id);

qualcuno e' in grado di aiutarmi? pls

ciao, teo

[teohell]

sta diventando un'abitudine rispondermi da solo
leggendo altri post qui sotto ho visto che a volte l'enterframe viene imposto a _root invece che al movieclip... pero' c'e' qualcosa che non capisco, non dovrebbe essere la stessa cosa??
perche' mettendo _root.OnEnterFrame funziona mentre con clip.OnEnterFrame non funziona?????? e nemmeno con this.OnEnterFrame???
se il clip e' in loop teoricamente dovrebbe continuare a entrare nel frame 1 (l'unico che possiede) e quindi dovrebbe andare... e invece no! perche'?

ciao, teo

[negatyve]

Il problema è che non puoi impostare l'enterFrame nello stesso movieclip dove carichi il filmato, perchè quest'ultimo distrugge tutte le variabili precedenti (compreso l'enterframe). Fai così:

//preload
function preload() {
	clip.onEnterFrame = function()
	{
		var tot = clip.loader.getBytesTotal();
		var car = clip.loader.getBytesLoaded();
		if (car > 1024 && (car >= tot)) {
			//setto dimensioni
			clip.loader._height = 192;
			clip.loader._width = 256;
			clip._visible = true;
			//cancello enterframe
			delete clip.onEnterFrame;
		}
	};
}
//definisco l'oggetto
myVars = new LoadVars();
//caricamento immagine
myVars.onLoad = function(success)
{
	if (success) {
		clip.createEmptyMovieClip("loader", 1);
		clip.loader.loadMovie(this.immagine);
		clip._visible = false;
		preload();
	} else {
		trace("Errore");
	}
};
//chiamata metodo load all'oggetto loadvars
myVars.load("product_info_2.php?products_id=" +_root.products_id);