[VB6] Completamento automatico

[Dave Pantera]

Qualcuno sa se esiste una funzione di completamento automatico per le combobox in VB6.0?

[raffaeu]

Si gioia cara io ho fatto questa ...
Chiaramente devi prima popolare la comboBox e impostare lo Style = 0

Dichiarazione
Private miSelStart As Integer
Questo per non far fare danni all' utente
Private Sub cmbCitta_KeyDown(KeyCode As Integer, Shift As Integer)
    miSelStart = cmbCitta.SelStart
End Sub
Completamento
Private Sub cmbCitta_KeyPress(KeyAscii As Integer)
    Dim lCnt       As Long 'Generic long counter
    Dim lMax       As Long
    Dim sComboItem As String
    Dim sComboText As String 'Text currently in combobox
    Dim sText      As String 'Text after keypressed

    With cmbCitta
        lMax = .ListCount - 1
        sComboText = .Text
        sText = Left(sComboText, miSelStart) & Chr(KeyAscii)
        
        KeyAscii = 0 'Reset key pressed
        
        For lCnt = 0 To lMax
            sComboItem = .List(lCnt)
            
            If UCase(sText) = UCase(Left(sComboItem, _
                                         Len(sText))) Then
                .ListIndex = lCnt
                .Text = sComboItem
                .SelStart = Len(sText)
                .SelLength = Len(sComboItem) - (Len(sText))
                
                Exit For
            End If
        Next 'lCnt
    End With
End Sub

Funzia benone!!