upload

[marco25b]

Ciao a tutti!!
Qualcuno sa dirmi dove posso trovare uno script per l' upload che dia la possibilità di impostare il peso ed il tipo di file da "caricare"?? (su internet niente ho trovato )

Questo è lo scrpt che adopero ma nn mi da la possibilità di fare quelle operazioni. Come posso modificarlo??

<%Sub BuildUploadRequest(RequestBin)
PosBeg = 1
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
boundaryPos = InstrB(1,RequestBin,boundary)
Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--")))
Dim UploadControl
Set UploadControl = CreateObject("Scripting.Dictionary")
Pos = InstrB(BoundaryPos,RequestBin,getByteString("Conte nt-Disposition"))
Pos = InstrB(Pos,RequestBin,getByteString("name="))
PosBeg = Pos+6
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
PosFile = InstrB(BoundaryPos,RequestBin,getByteString("filen ame="))
PosBound = InstrB(PosEnd,RequestBin,boundary)
If PosFile<>0 AND (PosFile<PosBound) Then
PosBeg = PosFile + 10
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
UploadControl.Add "FileName", FileName
Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:"))
PosBeg = Pos+14
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
UploadControl.Add "ContentType",ContentType
PosBeg = PosEnd+4
PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
Else
Pos = InstrB(Pos,RequestBin,getByteString(chr(13)))
PosBeg = Pos+4
PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
End If
UploadControl.Add "Value" , Value
UploadRequest.Add name, UploadControl
BoundaryPos=InstrB(BoundaryPos+LenB(boundary),Requ estBin,boundary)
Loop
End Sub
Function getByteString(StringStr)
For i = 1 to Len(StringStr)
char = Mid(StringStr,i,1)
getByteString = getByteString & chrB(AscB(char))
Next
End Function
Function getString(StringBin)
getString =""
For intCount = 1 to LenB(StringBin)
getString = getString & chr(AscB(MidB(StringBin,intCount,1)))
Next
End Function%>

Grazie a tutti in anticipo

[Certe Notti]

Originariamente inviato da marco25b
Ciao a tutti!!
Qualcuno sa dirmi dove posso trovare uno script per l' upload che dia la possibilità di impostare il peso ed il tipo di file da "caricare"?? (su internet niente ho trovato )

Questo è lo scrpt che adopero ma nn mi da la possibilità di fare quelle operazioni. Come posso modificarlo??




Grazie a tutti in anticipo

se vuoi ti passo quello che uso io, ti permette di sacegliere il tipo di file .zip, .pdf ecc da uplodare, ti permette di alterare il limite massimo del peso del file, e ti permette pure di rinominare il file del tipo che se il file si chiama iscrizione.pdf tu puoi dirgli di chiamarlo iscrizione_mesa_anno.pdf a seconda delle info che ritieni utile il file contenga nel suo nome.

[marco25b]

ciao .. si grazie saresti gentilissimo

[Certe Notti]

allora:

ti crei una pagina e la chiami upload.asp, è il motore del sistema di upload e il codice è:

<%Sub BuildUploadRequest(RequestBin)	
	PosBeg = 1
	PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
	boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
	boundaryPos = InstrB(1,RequestBin,boundary)
	Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--")))
		Dim UploadControl
		Set UploadControl = CreateObject("Scripting.Dictionary")
		Pos = InstrB(BoundaryPos,RequestBin,getByteString("Content-Disposition"))
		Pos = InstrB(Pos,RequestBin,getByteString("name="))
		PosBeg = Pos+6
		PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
		Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		PosFile = InstrB(BoundaryPos,RequestBin,getByteString("filename="))
		PosBound = InstrB(PosEnd,RequestBin,boundary)
		If  PosFile<>0 AND (PosFile<PosBound) Then
			PosBeg = PosFile + 10
			PosEnd =  InstrB(PosBeg,RequestBin,getByteString(chr(34)))
			FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "FileName", FileName
			Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:"))
			PosBeg = Pos+14
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
			ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "ContentType",ContentType
			PosBeg = PosEnd+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
			Else
			Pos = InstrB(Pos,RequestBin,getByteString(chr(13)))
			PosBeg = Pos+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		End If
		UploadControl.Add "Value" , Value	
		UploadRequest.Add name, UploadControl	
		BoundaryPos=InstrB(BoundaryPos+LenB(boundary),RequestBin,boundary)
	Loop
  End Sub
  Function getByteString(StringStr)
	For i = 1 to Len(StringStr)
		char = Mid(StringStr,i,1)
		getByteString = getByteString & chrB(AscB(char))
	Next
  End Function
  Function getString(StringBin)
	getString =""
	For intCount = 1 to LenB(StringBin)
		getString = getString & chr(AscB(MidB(StringBin,intCount,1))) 
	Next
  End Function%>

dopo di che nella pagina dove permetti la selezione del file metti questo form:

 <form enctype="multipart/form-data" method="post" action="nomepagina.asp">

ed infine in nomepagina.asp

<%

  Response.Expires=0
  Response.Buffer = TRUE
  Response.Clear
  byteCount = Request.TotalBytes
  RequestBin = Request.BinaryRead(byteCount)
  Dim UploadRequest
  Set UploadRequest = CreateObject("Scripting.Dictionary")

  BuildUploadRequest  RequestBin
  contentType = UploadRequest.Item("foto").Item("ContentType")
  filepathname = UploadRequest.Item("foto").Item("FileName")
  filename = Right(filepathname,Len(filepathname)-InstrRev(filepathname,"\"))
  value = UploadRequest.Item("foto").Item("Value")

 
 NA = Session("NumArticolo")
 ED = Session("NumED")
 
 flag=0
	
	
 if cstr(filepathname)<>"" then	


  if LenB(value)<=300000 then
  
	  if ucase(cstr(Right(cstr(filepathname),4)))=".BMP" or ucase(cstr(Right(cstr(filepathname),4)))=".JPG" or ucase(cstr(Right(cstr(filepathname),4)))=".GIF" or ucase(cstr(Right(cstr(filepathname),4)))=".TIF" then  


		  filename="Articolo" & cstr(NA) & "_" & cstr(ED) & cstr(Right(cstr(filepathname),4))
	
		  'Create FileSytemObject Component
		  Set ScriptObject = Server.CreateObject("Scripting.FileSystemObject")
		
		  'Create and Write to a File
		  pathEnd = Len(Server.mappath(Request.ServerVariables("PATH_INFO")))-14
		  
          Set MyFile = ScriptObject.CreateTextFile(Server.MapPath("\") & "/public/" & filename)
		 
		  For i = 1 to LenB(value)
			 MyFile.Write chr(AscB(MidB(value,i,1)))
		  Next
		  MyFile.Close

		  
	  else
	  	flag=2
	  end if
	  
  
  else
  	flag=1
  end if

	else
		flag=3
	end if
	


  if cint(flag)=0 then
  	 response.redirect("ins_striscia_reg2.asp?filename=" & filename)
  else
  	 response.redirect("inserimento_striscia_foto.asp?Errore=" & flag)	
  end if

%>

apportando ovviamente le dovute modifiche!

ciao