OWC10.ChartSpace

[Gamma]

Ciao a tutti.

Ho un win2k server senza office.
Dovrei poter creare grafici con l'oggetto OWC10.ChartSpace ho trovato su www.microsoft.com/downloads/details.aspx?FamilyID=982b0359-0a86-4fb2-a7ee-5f3a499515dd&displaylang=it il download del file owc10.exe. Posso installarlo o me lo sconsigliate?
Grazie

[Gamma]

Nessuno può consigliarmi?

[morphy79]

installa... con quello ci fai delle cosette carine tipo creazioni grafici e interazione con excel

[morphy79]

se poi hai bisogno una mano io ci sono, anzi ti referenzio il codice che uso io :

    
			<%
			'Creiamo l'oggetto
			Set ChartObj = Server.CreateObject("OWC10.ChartSpace")

			Set ChartConsts = ChartObj.Constants
			set NewChart = ChartObj.Charts.Add

			'Settiamo il tipo di grafico, il 13 è con i puntini, il 12 senza, 1 istogramma, 46 istogramma 3D
			NewChart.Type = 1
	
			'Passiamo i valori al grafico
			Set Serie = NewChart.SeriesCollection.Add

			Serie.SetData ChartConsts.chDimCategories, ChartConsts.chDataLiteral, ARR_CSZFE

			Serie.SetData ChartConsts.chDimValues, ChartConsts.chDataLiteral, ARR_PESSIMISTA_MINUTI
			
			'set up some additional properties
			'add and format the chart title
			
			NewChart.HasTitle = True
			NewChart.Border.Color = "#336699"	' colore del bordo della tabella
			NewChart.HasLegend = False       ' visualizza o meno la legenda
			NewChart.SeriesCollection(0).Caption = "PROVE"   ' testo della legenda

			' TITOLO
			NewChart.Title.Caption = "Tempo Pessimistico Blocco Front End"
			set objFont = NewChart.Title.Font
			objFont.Name = "Verdana"
			objFont.Size = 14
			objFont.Bold = False
			objFont.Color = "#313294"

			' ASSE VERTICALE
			set objAxis = NewChart.Axes(ChartConsts.chAxisPositionBottom)
			objAxis.HasTitle = True
			objAxis.Title.Caption = "FRONT END"
			set objFont = objAxis.Title.Font
			objFont.Name = "Verdana"
			objFont.Size = 11
			objFont.Bold = False
			objFont.Color = "#313294"

			' ASSE ORIZZONTALE
			set objAxis = NewChart.Axes(ChartConsts.chAxisPositionLeft)
			'objAxis.NumberFormat = "." 
			objAxis.HasTitle = True
			objAxis.Title.Caption = "TEMPO BLOCCO ( Min )"
			set objFont = objAxis.Title.Font
			objFont.Name = "Verdana"
			objFont.Size = 11
			objFont.Bold = False
			objFont.Color = "#313294"
	
			' COLORI INTERNI DEL GRAFICO
			NewChart.PlotArea.Interior.Color = "#EAEEE9"
			NewChart.SeriesCollection(0).Interior.Color = "#336699"		' per grafico istogramma 
			NewChart.SeriesCollection(0).Line.Color = "#65B9E2"	' per grafico a linee		
			
			'Settiamo il path dell'immagine che verrà creata
			ImagePath=server.mappath(gruppo & "_BLOCCO_AGGIORNAMENTI_PESSIMISTA.gif")
			'Salviamo l'immagine
			ChartObj.ExportPicture ImagePath,"gif", 600, 350
			set oChart=nothing

			response.write "[img]../images/transp.gif[/img]"

			%>

			<script> 
			<%="document.getElementById('GRAFICO_1').src='" & gruppo & "_BLOCCO_AGGIORNAMENTI_PESSIMISTA.gif'"%>
			</script>

ciao !!!!

[Gamma]

quindi funge anche senza office, giusto?

[morphy79]

si si... vai tranquillo... da qualche parte dicono di no, ma ti assicuro che funziona da dio !!!!!!!!

è una cosa veramente vantaggiosa, specialmente per i grafici !!!

[Gamma]

Ieri non ho fatto in tempo a ringraziarti, morphy79. L'installazione è stata fatta ed il tutto funziona correttamente.
Una questione per te:
per il colore si usa NewChart.PlotArea.Interior.Color = "#EAEEE9",
sai se è prevista invece una proprietà od un metodo per inserire un'immagine in plotArea?