lista swf da txt

[enigma_79]

allora il mio problema è questo.

ho una lista in un file txt

file1.swf
file2.swf
file3.swf
......
filen.swf

ora devo fare in modo di caricare il file

file1.swf leggendolo da txt poi quando termina l'esecuzione di file1, in automatico deve caricarmi il file2.swf e così via

per poi ripartire dall'uno

come posso fare?

[jeck]

Te la butto li, leggi i valori dal file di teso, e li metti in un array, poi ti fai una funzione ricorsiva che legge il primo fa il preload e quando terminato incrementa un numero(i file da caricare) poi richiama se stessa, la viabile da incrementare ti serve per pescare i valori dall'array.

[andr3a]

aspe' ... dove vuoi caricare tutti questi swf ??
sempre sullo stesso posto o in movies differenti ?

[andr3a]

vabbeh ... lo riscrivo, questo dovrebbe automatizzarti il tutto ...

this._lockroot = true;

var swfloader:Object = new Object();

// a caricamento effettuato
swfloader.onLoadInit = function( mc:MovieClip ):Void {
	if( this.__container[ this.__containerNum ] != undefined ) {
		this.loadMovie( this.__container[ this.__containerNum++ ] );
	}
}

// durante il caricamento
swfloader.onLoadProgress = function( mc:MovieClip, bl:Number, bt:Number ):Void {
	var p:Number = Math.floor( ( bl / bt ) * 100 );
	if( p != NaN && p != infinity && p > 0 ) {
		trace( mc + ', ' + p );
	}
}

// in errore caricamento
swfloader.onLoadError = function( mc:MovieClip, error:String ):Void {
	trace( error );
}

// funzione di inizializzazione caricamento
swfloader.loadMovie = function( swf:String ):Void {
	if( this.__ML__ != undefined ) {
		delete this.__ML__;
	}
	_root.createEmptyMovieClip( swf, _root.getNextHighestDepth() );
	this.__ML__ = new MovieClipLoader();
	this.__ML__.addListener( this );
	this.__ML__.loadClip( swf, _root[swf] );
}

// funzione di caricamento valori dal file di testo
swfloader.preload = function( txtFile:String ):Void {
	var __lv__:LoadVars = new LoadVars();
	__lv__.__path = this;
	__lv__.onLoad = function( s:Boolean ):Void {
		if( s == true ) {
			this.__path.__container = new Array();
			var a:Number = 0;
			while( this['file'+String(a)] != undefined ) {
				this.__path.__container.push( this['file'+String( a++ )] );
			}
			this.__path.__containerNum = new Number( this.__path.__container.length - 1 );
			this.__path.loadMovie( this.__path.__container[ this.__path.__containerNum++ ] );
		}
		else {
			this.__path.onLoadError( _root, 'Impossibile caricare il file: ' + txtFile );
		}
	}
	__lv__.load( txtFile );
}

// avvio il processo ...
swfloader.preload( 'file_di_testo.txt' );

[enigma_79]

ciao And3a e grazie per l'interessamento al mio tread.

Ti spiego ho un txt che si chiama file.txt che avrà questa struttura

file=pippo.swf&pluto.swf&paperino.swf

quindi i nomi non saranno 01-02 ecc.. sequenziali ma avranno nomi differenti

io devo caricarli in ordine di come vengono scritti sul file di testo.
in un mc che istanzio container

in questo caso carico pippo.swf lo eseguo, finita l'esecuzione di pippo caricherò pluto.swf e lo eseguo ecc....

In maniera che se cambio l'ordine nel file di testo cambi l'ordine di esecuzione dei filmati e arrivato all'ultimo dovrà ripartire a caricare il primo.

Va bene il codice che mi hai passato?

Una domanda.

Se io con questo file creo un proiettore .exe

E' possibile fare in modo che questo .exe parta in automatico all'avvio del pc? insomma come se fosse un autorun da cd ma che avviene all'avvio di windows.

Grazie

[enigma_79]

up

[andr3a]

codice sul keyframe del file main.fla

this._lockroot = true;

// CREO IL CONTENITORE
this.createEmptyMovieClip( 'container', this.getNextHighestDepth() );


// CREO IL GESTORE DI EVENTI
var swfloader:Object = new Object();

// a caricamento effettuato
swfloader.onLoadInit = function( mc:MovieClip ):Void {
	_root['container'].gotoAndStop( 1 );
	_root['container']._visible = true;
	_root['container'].__path = this;
	_root['container'].onEnterFrame = function() {
		if( this._currentframe < this._totalframes ) {
			this.gotoAndStop( ++this._currentframe );
		}
		else {
			if( this.__path.__container[ this.__path.__containerNum ] != undefined ) {
				this.__path.loadMovie( this.__path.__container[ this.__path.__containerNum++ ] );
			}
			delete this.onEnterFrame;
		}
	}
}

// durante il caricamento
swfloader.onLoadProgress = function( mc:MovieClip, bl:Number, bt:Number ):Void {
	var p:Number = Math.floor( ( bl / bt ) * 100 );
	if( p != NaN && p != infinity && p > 0 ) {
		trace( mc + ', ' + p );
	}
}

// in errore caricamento
swfloader.onLoadError = function( mc:MovieClip, error:String ):Void {
	trace( error );
}

// funzione di inizializzazione caricamento
swfloader.loadMovie = function( swf:String ):Void {
	_root['container']._visible = false;
	if( this.__ML__ != undefined ) {
		_root['container'].unloadMovie();
		delete this.__ML__;
	}
	this.__ML__ = new MovieClipLoader();
	this.__ML__.addListener( this );
	this.__ML__.loadClip( swf, _root['container'] );
}

// funzione di caricamento valori dal file di testo
swfloader.preload = function( txtFile:String ):Void {
	var __lv__:LoadVars = new LoadVars();
	__lv__.__path = this;
	__lv__.onLoad = function( s:Boolean ):Void {
		if( s == true ) {
			this.__path.__container = new Array();
			var a:Number = 0;
			while( this['file'+String(a)] != undefined ) {
				this.__path.__container.push( this['file'+String( a++ )] );
			}
			this.__path.__containerNum = new Number( 0 );
			this.__path.loadMovie( this.__path.__container[ this.__path.__containerNum++ ] );
		}
		else {
			this.__path.onLoadError( _root, 'Impossibile caricare il file: ' + txtFile );
		}
	}
	__lv__.load( txtFile );
}

// avvio il processo ...
swfloader.preload( 'file.txt' );

testo all' interno del file file.txt

&file0=pippo.swf&
&file1=pluto.swf&
&file2=paperino.swf&

altri SWF nella stessa carella:
pippo.swf
pluto.swf
paperino.swf


sono tornato ora, scusa il ritardo



esempio completo
http://andr3a.dotgeek.org/ENIGMA.zip

[enigma_79]

sono io che mi scuso per il disturbo, e come al solito,

grazie per l'aiuto.

[andr3a]

dimenticavo ...

Originariamente inviato da enigma_79

E' possibile fare in modo che questo .exe parta in automatico all'avvio del pc? insomma come se fosse un autorun da cd ma che avviene all'avvio di windows.

prendi un qualunque cd che ti fa l' autorun, copia il file autorun.inf sulla root del CD che andrai a creare, modifica il file eseguibile da aprire e l' eventuale icona

[enigma_79]

Hai idea di come far partire la cosa direttamente all'accensione di un pc.

un autorun di main.exe all'accensione del pc

grazie per la pazienza che hai