classe preloader as2

[zeropunto]

Ciao, vorrei sapere se qualcuno conosce una classe da importare come preload.. che funzioni quindi con AS2..

Praticamente vorri fare una cosa tipo:

import classePreload.as;

e poi richiamare il preload quando mi serve potendone variare alcuni parametri tipo file da caricare posizione del preload e preload stesso

quindi tipo:

mcVuoto.preload(file, _x, _y, barra_mc, funzioneFinale)

file = file da caricare
_x = posizione x della barra di avanzamento
_y = posizione y della barra di avanzamento
barra_mc = movieclip da usare come barra di avanzamento
funzioneFinale = funzione da richiamare una volta completato il caricamento
Come posso fare?

[bazzdepolo]

Penso non esista, ma puoi sempre fare una cosa del genere con le funzioni...sai prima fai una funzione generale e poi quando la richiami gli passi le variabili....

[negatyve]

Per fortuna c'è, è la classe MovieClipLoader (cerca nella guida). Un esempio:

// creiamo un movieclip vuoto in cui caricare l'immagine
var mc:MovieClip = this.createEmptyMovieClip("contenitore", 1);
// creiamo un'istanza della classe MovieClipLoader
var loader:MovieClipLoader = new MovieClipLoader();
// creiamo un oggetto generico che funga da ricettore
// per gli eventi generati dall'oggetto "loader
var listener:Object = new Object();
// mettiamo l'oggetto "listener" in ascolto
loader.addListener(listener);
// definiamo tutti i gestori degli eventi inviati da "loader"
// funzione da eseguire non appena è iniziato lo scaricamento del file
listener.onLoadStart = function(clip:Object):Void
{
	trace("caricamento iniziato");
};
// funzione da eseguire ogni volta che viene scaricata
// una nuova porzione del file
listener.onLoadProgress = function(clip:Object):Void
{
	var progress:Object = loader.getProgress(clip);
	trace("car: " + progress.bytesLoaded);
	trace("tot: " + progress.bytesTotal);
	trace("***************************");
};
// funzione da eseguire non appena terminato il caricamento
listener.onLoadComplete = function(clip:Object):Void
{
	trace("caricamento completato");
};
// funzione da eseguire una volta che le azioni del primo
// frame del filmato esterno sono state eseguite, quando
// cioè il filmato è completamente referenziabile
listener.onLoadInit = function(clip:Object):Void
{
	trace("contributo esterno inizializzato");
};
// funzione da eseguire nel caso in cui fallisca il caricamento
listener.onLoadError = function(clip:Object, errore:String):Void
{
	trace("caricamento fallito: " + errore);
};
// caricamento del file
loader.loadClip("tuo_file.ext", mc);

[zeropunto]

ho trovato in riguardo questo articolo con file .as annesso
http://www.moock.org/blog/archives/000060.html che ne dite?

[negatyve]

Che Colin Moock, al tempo dell'actionscript 1.0 e del flash player 6, aveva dato inizio ad una "petizione" perchè col flash player 7 venisse creata una Classe per il preloader con un'API comune per tutti i media caricabili, che si trattasse di jpg , swf o mp3. E che con il Flash MX 2004 e il Flash Player 7 è stato accontentato, dato che hanno creato la Classe MovieClipLoader di cui ti ho scritto un esempio.

[zeropunto]

Ma sai veramente un sacco di cose..
curiosità: ma esiste qualcosa che tu non sai?

Quindi usare quella di Flash o quella di Colin Moock è la stessa cosa, o una può essere migliore dell'altra? :master:

[negatyve]

>ma esiste qualcosa che tu non sai?

un'infinità, purtroppo..

>Quindi usare quella di Flash o quella di Colin Moock è la
>stessa cosa, o una può essere migliore dell'altra?

Usa pure quella di Flash, che è stata creata proprio seguendo le indicazioni di quella di moock (infatti se non ricordo male i metodi e le proprietà hanno gli stessi identici nomi).
Queste cose le so perchè Moock è il mio mito personale..