Apertura file pdf

[pegaso22]

Ciao a tutti,
vengo da una discussione sul forum html che riguarda le modalità di apertura di file linkati.
Mi servirebbe poter far scaricare un file pdf e non farlo aprire nel browser.
Riporto di seguito ciò che mi hanno scritto lì


Quando un utente vuole scaricare un file,prima che il server carichi il file da inviare, invii al browser i cosidetti "header" ossia intestazioni che non si vedono ma che il browser può interpretare, che dicono al browser appunto di scaricare il file e non di trovare un applicativo in grado di aprirlo(questo generalmente avviene con internet explorer).
Quindi inviando queste istruzioni prima di inviare il reale contenuto della pagina(che nel tuo caso è un file) riesci ad ottenere lo scaricamento e non l'apertura automatica del file stesso.

Qualcuno sa darmi una mano?
Fatemi sapere.
Grazie mille.

[Galex]

in pratica un modo epr forzare il download di un file?
io uso questo

FileSize=Dimensioni del file da scaricare
FileName=Nome da dare al file che scarico
FileFullPath=Nome e percorso del file da scaricare

Response.Clear
        Dim adoStream
        Set adoStream = Server.CreateObject("ADODB.Stream")
          adoStream.Open()
          adoStream.Type = 1
          adoStream.LoadFromFile FileFullPath
          Response.AddHeader "Content-Disposition", "attachment;filename=" & FileName
      		Response.AddHeader "Content-Length", FileSize

          Response.ContentType = "application/octet-stream"
          Response.BinaryWrite(adoStream.Read())
          adoStream.Close
        Set adoStream = Nothing
        Response.End

[pegaso22]

Grazie, provo poi se ho problemi ti faccio sapere.

[fedrok]

Originariamente inviato da Galex
in pratica un modo epr forzare il download di un file?
io uso questo

FileSize=Dimensioni del file da scaricare
FileName=Nome da dare al file che scarico
FileFullPath=Nome e percorso del file da scaricare

Response.Clear
        Dim adoStream
        Set adoStream = Server.CreateObject("ADODB.Stream")
          adoStream.Open()
          adoStream.Type = 1
          adoStream.LoadFromFile FileFullPath
          Response.AddHeader "Content-Disposition", "attachment;filename=" & FileName
      		Response.AddHeader "Content-Length", FileSize

          Response.ContentType = "application/octet-stream"
          Response.BinaryWrite(adoStream.Read())
          adoStream.Close
        Set adoStream = Nothing
        Response.End

Funziona!!!
Nota: fileSize va espresso in BYTES!

[Galex]

wow,certo che dal 14 luglio...

[fedrok]

Ciao.
Partendo dallo script suggerito da Galex, ho sviluppato del codice un po' più autonomo, al quale basta conoscere il full path del file sul quale forzare il download.

Lo allego qui sotto:

<%@ Language = "VBScript" %>
<% option explicit

Dim  fileSize , fileName , FileFullPath
'FileSize=Dimensioni del file da scaricare in BYTES
'FileName=Nome da dare al file che scarico
'FileFullPath=Nome e percorso del file da scaricare

fileFullPath = "c:\nomefile.ext"		' Inserire qui il fullPath del file da downloadare.


Dim fso, fileObj
Set fso = CreateObject("Scripting.FileSystemObject")
Set fileObj = fso.GetFile(FileFullPath) 

fileSize = fileObj.size  
fileName = fileObj.name


Set fileObj = nothing
Set fso = nothing


Response.Clear

Dim adoStream
Set adoStream = Server.CreateObject("ADODB.Stream")
adoStream.Open()
adoStream.Type = 1
adoStream.LoadFromFile fileFullPath
Response.AddHeader "Content-Disposition", "attachment;filename=" & fileName
Response.AddHeader "Content-Length", fileSize
Response.ContentType = "application/octet-stream"
Response.BinaryWrite( adoStream.Read() )
adoStream.Close
Set adoStream = Nothing


%>

E' testato e funzionante.
Basta personalizzarlo inserendo il valore a piacere della variabilefileFullPath.