[vbscript] visualizzare ip

[oronze]

ho preso questo esempio dal sito della microsoft e l'ho adattato alle mie esigenze (usare vbscript con desktopx)

Dim objWMIService

Sub Object_OnScriptEnter
  object.settimer 123, 1000
  Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
  Object_OnTimer123
End Sub
 
Sub Object_OnScriptExit
 Set objWMIService = nothing
End Sub

Sub Object_OnTimer123
 Set IPConfigSet = objWMIService.ExecQuery("Select IPAddress from Win32_NetworkAdapterConfiguration")

For Each IPConfig In IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i = LBound(IPConfig.IPAddress) To UBound(IPConfig.IPAddress)
        Object.text = "Ip:" & IPConfig.IPAddress(i)
        Next
    End If
Exit Sub
 Next
End Sub

è da poco che conosco vbscript ma non mi sembra ci siano errori....ora, perchè non mi stampa nulla? neanche Ip:?

[cavicchiandrea]

Originariamente inviato da oronze
ho preso questo esempio dal sito della microsoft e l'ho adattato alle mie esigenze (usare vbscript con desktopx)

Dim objWMIService

Sub Object_OnScriptEnter
  object.settimer 123, 1000
  Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
  Object_OnTimer123
End Sub
 
Sub Object_OnScriptExit
 Set objWMIService = nothing
End Sub

Sub Object_OnTimer123
 Set IPConfigSet = objWMIService.ExecQuery("Select IPAddress from Win32_NetworkAdapterConfiguration")

For Each IPConfig In IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i = LBound(IPConfig.IPAddress) To UBound(IPConfig.IPAddress)
        Object.text = "Ip:" & IPConfig.IPAddress(i)
        Next
    End If
Exit Sub
 Next
End Sub

è da poco che conosco vbscript ma non mi sembra ci siano errori....ora, perchè non mi stampa nulla? neanche Ip:?

Premesso che non ho verificato lo script, xchè non stampa niente non vuole necessariamente dire che ci siano degli errori nello script.
Detto questo io conosco vbscript lato server x indederci ASP e non sò se esiste vbscript lato client.
Anche xchè non credo si possa rilevare l'ip dal client ma solo utilizzando un linguaggio server.

[oronze]

anche io non pensavo fosse possibile ma è sul sito della microsoft (mi sa che msdn o qualcosa di simile)....dato che non lo eseguo in un browser ma viene processato da una applicazione forse è posibile....

[cavicchiandrea]

Originariamente inviato da oronze
anche io non pensavo fosse possibile ma è sul sito della microsoft (mi sa che msdn o qualcosa di simile)....dato che non lo eseguo in un browser ma viene processato da una applicazione forse è posibile....

Scusa la domanda ma lo script postato l'hai provato in rete racchiuso trai tag

<% %>

su di un server che supporti asp?

[Alethesnake]

in quel codice manca la chiamata alla sub principale, è normale che eseguendo il vbs non succeda niente.
ma sul sito c'era solo quello? prova a postare il link alla pagina dalla quale l'hai preso

[oronze]

non trovo più il link di quel sito cmq lo script originale era questo

strComputer = "."
Set objWMIService = GetObject( _ 
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
    ("Select IPAddress from Win32_NetworkAdapterConfiguration ")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i=LBound(IPConfig.IPAddress) _
            to UBound(IPConfig.IPAddress)
                WScript.Echo IPConfig.IPAddress(i)
        Next
    End If
Next

io l'ho modificato ma altri modificati così funzionano....

cmq non l'ho messo in rete....questi codici li interfaccio con una applicazione (DesktopX) forse è per questo che non funzionano?

[Alethesnake]

Originariamente inviato da oronze
non trovo più il link di quel sito cmq lo script originale era questo

strComputer = "."
Set objWMIService = GetObject( _ 
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
    ("Select IPAddress from Win32_NetworkAdapterConfiguration ")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i=LBound(IPConfig.IPAddress) _
            to UBound(IPConfig.IPAddress)
                WScript.Echo IPConfig.IPAddress(i)
        Next
    End If
Next

io l'ho modificato ma altri modificati così funzionano....

cmq non l'ho messo in rete....questi codici li interfaccio con una applicazione (DesktopX) forse è per questo che non funzionano?

ho provato questo codice (in un file vbs) e mi restituisce un msgbox con il mio ip.
nella tua modifica oltre a mancare una chiamata alla routine principale di avvio dell'applicazione c'è un riferimento ad un oggetto che non viene istanziato da nessuna parte (object)
se mi dici cosa vuoi fare magari posso darti una mano a risistemarlo

[oronze]

io per il momento ho modificato alcuni script già forniti con il programma....

Sub Object_OnScriptEnter
Object.SetTimer 444, 1000
End Sub

Sub Object_OnScriptExit
Object.KillTimer 444
End Sub

Sub Object_OnTimer444
Object.Text = now()
End Sub

è diventato

'Called when the scriptis executed
Sub Object_OnScriptEnter
Object.SetTimer 444, 1000
End Sub

'Called when the script is terminated
Sub Object_OnScriptExit
Object.KillTimer 444
End Sub

Sub Object_OnTimer444
Object.Text = UCase(left(FormatDateTime(Date, 1),1)) & LCase(mid(FormatDateTime(Date, 1),2)) & " " & Right("00" & CStr(hour(now())),2) & ":" & Right("00" & CStr(minute(now())),2) & ":" & Right("00" & CStr(second(now())),2)
End Sub

e questo funziona.....
poi, con l'aiuto della reference di microsoft ho creato questo che funziona comunque:

Dim objWMIService

Sub Object_OnScriptEnter
  object.settimer 123, 1000
  Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
  Object_OnTimer123
End Sub
 

'Let's clean it, as a good practice
Sub Object_OnScriptExit
 Set objWMIService = nothing
End Sub

Sub Object_OnTimer123
 Dim colItems, colItemsa
 Set colItems = objWMIService.ExecQuery("Select AvailableMBytes from Win32_PerfFormattedData_PerfOS_Memory",,48)
 Set colItemsa = objWMIService.ExecQuery("Select * from Win32_PerfFormattedData_PerfDisk_LogicalDisk where Name = 'D:'",,48)
 For Each objItem In colItems
   variabile = "Memoria disponibile: " & objItem.AvailableMBytes & " MB"
 Next
 For Each objItem In colItemsa
    Object.text = variabile & " Spazio disponibile: " & objItem.FreeMegabytes & " MB"
Exit Sub
 Next
End Sub

ora io vorrei var visualizzare un messaggio con scritto ip: ip della mia connessione internet....
come fare?

[Alethesnake]

non so se ho capito le tue intenzioni, ma potresti fare una cosa del genere, poi la showIpAdress l'aggiusti come ti serve:

private function ipAdress()
	Dim tmpArray(), cont
	cont = 0
	   
	strComputer = "."
	Set objWMIService = GetObject( _ 
			"winmgmts:\\" & strComputer & "\root\cimv2")
	Set IPConfigSet = objWMIService.ExecQuery _
			("Select IPAddress from Win32_NetworkAdapterConfiguration ")
	 
	For Each IPConfig in IPConfigSet
		If Not IsNull(IPConfig.IPAddress) Then 
			For i=LBound(IPConfig.IPAddress) _
						to UBound(IPConfig.IPAddress)
				
				ReDim preserve tmpArray(cont)
				tmpArray(cont) = IPConfig.IPAddress(i)
				cont = cont +1
			Next
		End If
	Next

	Set objWMIService = nothing
	Set IPConfigSet = nothing

	ipAdress = tmpArray
End Function


private sub showIpAdress(tmpArr)
	
	dim i
	if isArray(tmpArr) then
		For i=0 to UBound(tmpArr)
			msgbox tmpArr(i)
		next 'i
	else
		msgbox "Nessun indirizzo ip rilevato"
	end if
	
end sub



dim t
t=ipAdress

call showIpAdress(t)

[oronze]

funziona....ho solo cambiato msgbox con object.text....
sapresti anche darmene uno che fornisce la velocità di connessione (download di dati in quel momento....)
Cmq GRAZIEEEEE!!