ciao!
io vorrei cancellare tutti i files con una determinata estensione in una cartella..
come posso fare?
tnx!
ciao!
io vorrei cancellare tutti i files con una determinata estensione in una cartella..
come posso fare?
tnx!
Prova con questo ... puoi impostare pure di tenere i files più recenti .... questa è la versione 1.0 sono arrivato alla 2.1 ora ma non credo ti serva più di questo
Cia'
' DELLOG Vs 1.0 by Eas
' Cancella Log files by Eas
' Cancella i Log file più vecchi di N. giorni avvertendo via email sull'esito dell'operazione
' Questo File è Schedulato ogni 7 gg .
' Requisiti:
' Oggetto Scripting.FileSystemObject installato
' Oggetto Persits.MailSender installato
' Pollici da girare
' Varibili di default
VERSIONE = "DELLOG Vs 1.0 by Eas"
Ext = "log" ' Formato file selezionati
limite_tempo = 30 ' Tempo di mantenimento dei files
Test = True ' Se impostata a true non comanda la cancellazione ma invia solo il resoconto
' Variabili da modificare
fishost = "c:\winnt\system32\logfiles" ' Percorso da monitorare
Email = "xxx@xxx.it" ' Destinatario del resoconto
Emailhost = "smtp.xxx.it" ' Smtp per la spedizione dell'email
Set file = CreateObject("Scripting.FileSystemObject")
Set fileLOG = CreateObject("Scripting.FileSystemObject")
start = timer
dim Resoconto, N_FileEliminati, S_FileEliminati
Function GenerateAllFolderInformation(Folder)
Set Files = Folder.Files
on error resume next
For Each File In Files
if lcase(right(File.Name,len(Ext))) = Ext and datediff("d",File.DateLastModified,date()) => limite_tempo then
Resoconto = Resoconto & "Eliminato " & File.Path &" modificato " & formatdatetime(File.DateLastModified,1) & chr(10)
N_FileEliminati = N_FileEliminati + 1 ' Contatore numero file eliminati
S_FileEliminati = S_FileEliminati + File.Size ' Contatore dimensione file eliminati
if not test then File.delete
end if
next
End Function
set FolderLOG = fileLOG.GetFolder(fishost)
set FoldersLOG = FolderLOG.SubFolders
For Each SubFolder In FoldersLOG
Set SubFolderLOG = fileLOG.GetFolder(SubFolder.path)
call GenerateAllFolderInformation(SubFolderLOG)
set SubFolderLOG = nothing
next
set FoldersLOG = nothing
set FolderLOG = nothing
tempo = timer-start
TestoEmail = _
"Resoconto Eliminazione " & chr(10) & chr(13) & _
chr(10) & chr(13) & _
"Data : "& formatdatetime(date(),1) & chr(10) & _
"N File Eliminati : " & N_FileEliminati & chr(10) & _
"Dimensione Totale : " & formatnumber(S_FileEliminati,0) & " bytes" & chr(10) & _
"Tempo elaborazione : " & tempo & " secondi" & chr(10) & chr(13) & _
Resoconto & chr(10) & chr(13) & _
Versione
Set Mail = CreateObject("Persits.MailSender")
Mail.Host = Emailhost
Mail.Port = 25
Mail.From = "info@xxxx.it"
Mail.FromName = Versione
Mail.AddAddress email
Mail.Subject = "Resoconto " & VERSIONE
Mail.Body = TestoEmail
Mail.send 'toqueue
Mail.resetall
Set Mail = Nothing