Modifica script d'invio

[skyrob]

Salve,
vorrei modificare questo script (vedi sotto) in modo che all'arrivo mi arrivi nel corpo del messaggio il mittente, che salti di un paragrafo e poi il messaggio stesso. Non sapendo molto di asp non ne sono venuto a capo...
Ecco come vorrei che venisse:
Mittente: pinco pallino

testo del messaggio

Ecco lo script:

<%

' Controlla invio
if Request.QueryString("invia") = "true" AND Request.Form("submit") = "invia" then

Dim objMail, objConfig
' Crea l'oggetto email
Set objMail = CreateObject("CDO.Message")
' Dimensiona l'oggetto configurazione
Set objConfig = Server.CreateObject ("CDO.Configuration")
     
' Imposta le configurazioni
With objConfig
                        
' Server SMTP di uscita
' ATTENZIONE! Usare il proprio indirizzo di server email!
' E' FONDAMENTALE per l'invio della email
  .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.libero.it"

' Porta SMTP
  .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

' Porta CDO
  .Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

' Timeout
  .Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
  .Fields.Update
End With
     
' Assegna le configurazioni
Set objMail.Configuration = objConfig
     
' Assegna all'oggetto le proprietà necessarie
objMail.From = Request.Form("email") ' Mittente
objMail.To = "roby-p@libero.it" ' Destinatario
objMail.Subject = Request.Form("oggetto") ' Oggetto
objMail.HTMLBody = Request.Form("messaggio") ' Messaggio    

objMail.Send()

Set objMail = Nothing
     
Response.Write("Email inviata correttamente ")
Response.Write("all'indirizzo ")
Response.Write(Request.Form("email"))

else %>
<form name="formail" method="post" action="mailprova.asp?invia=true">
<table align="center" cellpadding="3" cellspacing="1">
<tr>
<td>Mittente</td>
<td><input type="text" name="mittente" /></td>
</tr>
<tr>
<td>Email</td>
<td><input type="text" name="email" /></td>
</tr>
<tr>
<td>Oggetto</td>
<td><input type="text" name="oggetto" /></td>
</tr>
<tr>
<td>Messaggio</td>
<td><textarea name="messaggio"></textarea></td>
</tr>
<tr>
<td colspan="2"> <input type="submit" value="invia" name="submit" /> </td>
</tr>
</table>
</form>
<% end if %>

Grazie

[cipcip]

sostituisci
questo

objMail.HTMLBody = Request.Form("messaggio") ' Messaggio

con questo:

objMail.HTMLBody = Request.Form("email")&"

"&Request.Form("messaggio") ' Messaggio

[skyrob]

Grazie mille!!!
Con questo tipo di sintassi posso personalizzare il tutto inserendo anche altri parametri presenti nel modulo, giusto?!