Il problema delle province e dei comuni

[natasha]

Buongiorno a tutti,
ho per voi un problema classico: ho una combo box per le province, ed una per i comuni.
La combo box per le province viene popolata da un database (Access); ovviamente, voglio che, una volta selezionata la provincia, la combo box dei comuni venga popolata (anch'essa da database) con tutti e soli i comuni appartenenti alla provincia selezionata.
Si accettano soluzioni multiple.
Kisses,

Nat

[kalosjo]

Nell'onchange della combo con le province, devi richiamare la apgina caricando tutti i comuni della provincia.

Se non sono stato chiaro richiama...

[natasha]

kalosjo, amico mio....
Mai venuto in mente che potevi mandare del codice?
Kisses,

Nat

[Mems]

Mostraci la struttura delle tabelle del database dove stanno i dati delle province e dei comuni e come i comuni sono relazionati alle province.

[natasha]

TAB_Province:

IDProvincia (PK)
NomeProvincia

Es.:

IDProvincia NomeProvincia
1 Palermo
2 Catania

TAB_Comuni:

IDComune (PK)
IDProvincia (FK)
NomeComune

Es.:

IDComune IDProvincia NomeComune
1 1 monreale
2 1 villabate
3 1 carini
4 2 paternò
5 2 zafferana etnea

[Fichico]

bhe .. per la select delle province fai come sql:

"SELECT * FROM TAB_Province ORDER BY NomeProvincia"

e ovviamente nei valori delle option metti come value l'id .. e fai visualizzare il nome della provincia

all'onchange della select .. fai un submit della stessa pagina .. dove ovviamente filtrerai i comuni in base all'id provincia, ovvero:

id = request.form("IDProvincia")

e l'sql:
"SELECT * FROM Tab_COMUNI WHERE IDProvincia = " & id & " ORDER BY NomeComune"

claro?

[natasha]

perdona l'ottusità.... ma veramente non puoi mandare il codice completo?
Kisses,

Nat

[michele.santoro]

Prova a dare un'occhiata qui "select-list dinamiche in puro asp. Puoi vedere l'esempio e scaricare lo script

[Mems]

<%
idProvincia = request.queryString("idProvincia")
if len(idProvincia) > 0 and isNumeric(idProvincia) then
idProvincia = cLng(idProvincia)
else
idProvincia = 0
end if

pagina = request.serverVariables("PATH_INFO")

set conn = server.createObject("ADODB.Connection")
conn.open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & server.mapPath("\mdb-database\database.mdb")
%>
<select name="province" onChange="location.href='<%=pagina%>?idProvincia='+this.value;">
<form>
<option value="0">SELEZIONA</option>
<%
sql = "SELECT * FROM TAB_PROVINCE ORDER BY NomeProvincia"
set rs = conn.execute(sql)
if not rs.eof then
do until rs.eof
%>
<option value="<%=rs("IDProvincia")%>"<% if rs("IDProvincia") = idProvincia then %> selected="selected"<% end if %>><%=rs("NomeProvincia")%></option>
<%
rs.moveNext
loop
end if
rs.close
set rs = nothing
%>
</select>
<% if idProvincia > 0 then %>
<select name="comuni">
<option value="0">SELEZIONA</option>
<%
sql = "SELECT * FROM TAB_COMUNI WHERE IDProvincia = " & idProvincia
set rs = conn.execute(sql)
if not rs.eof then
do until rs.eof
%>
<option value="<%=rs("IDComune")%>"><%=rs("NomeComune")%></option>
<%
rs.moveNext
loop
end if
rs.close
set rs = nothing
%>
</select>
<% end if %>
</form>

[natasha]

Funziona un amore, grazie