come impostare un azione goto da un movieclip

[maxbianchi]

Ciao, ho trovato questo script, ma non riesco a capire come e dove inserire l'azione che mi sposta da una scena all'altra
lo script lo applico su un MC per ottenere un comportamento da pulsante, grazie.

onClipEvent (load) {
	this.stop();
}
onClipEvent (mouseMove) {
	if (this.hitTest(_root._xmouse, _root._ymouse, false)) {
		if (!sopra) {
			sopra = true;
			if (!premutoFuori && !premutoDentro) {
				// on(rollOver)
				this.gotoAndStop(2);
				_parent.testo = "ROLL OVER";
				//-------------
			} else if (premutoDentro) {
				// on(dragOver)
				this.gotoAndStop(3);
				_parent.testo = "DRAG OVER";
				//-------------
			}
		}
	} else {
		if (sopra) {
			sopra = false;
			if (!premutoFuori && !premutoDentro) {
				// on(rollOut)
				this.gotoAndStop(1);
				_parent.testo = "ROLL OUT";
				//------------
			} else if (premutoDentro) {
				// on(dragOut)
				this.gotoAndStop(2);
				_parent.testo = "DRAG OUT";
				//------------
			}
		}
	}
	updateAfterEvent();
}
onClipEvent (mouseDown) {
	if (sopra) {
		// on(press)
		this.gotoAndStop(3);
		_parent.testo = "PRESS";
		/*** DOUBLE CLICK ROUTINE ***

		if (getTimer()-click<300) {
			// double click
			_parent.testo = "PRESS DOUBLE CLICK";
		} else {
			click = getTimer();
			// single click
			_parent.testo = "PRESS SINGLE CLICK";

		}***************************/
		premutoDentro = true;
	} else {
		premutoFuori = true;
	}
	updateAfterEvent();
}
onClipEvent (mouseUp) {
	if (premutoDentro && sopra) {
		// on(release)
		this.gotoAndStop(2);
		_parent.testo = "RELEASE";
		//------------
	} else if (premutoDentro && !sopra) {
		// on(releaseOutside)
		this.gotoAndStop(1);
		_parent.testo = "RELEASE OUTSIDE";
		//-------------------
	} else if (premutoFuori && sopra) {
		// on(rollOver)
		this.gotoAndStop(2);
		_parent.testo = "ROLL OVER";
		//-------------
	}
	premutoDentro = premutoFuori = false;
	updateAfterEvent();
}

Grazie per l'aiuto,

[NAP]

Non basta usare "uno script qualunque", fra l'altro meramente didattico, associandolo a chissà quale contesto (il tuo). Cmq, laddove c'è il commento per l'azione on (press) devi sostituire (non aggiungere):

this.gotoAndStop(3);

con:

_root.gotoAndPlay ("nomeEtichettaDelFrameDaRaggiungere");

Sai come si assegna un nome di etichetta ad un frame?

Qualche minuto dopo:

Se il tuo intento è quello di usare un MC come se fosse un pulsante, non occorre altro che assegnargli le azioni tipiche di un pulsante:

on (rollOver) { // quando il puntatore va sul MC
// fai questa cosa;
}
on (rollOut) { // quando il puntatore va via dal MC
// fai questa cosa;
}
on (press) { // quando premi col mouse sul MC
// fai questa cosa;
}
on (release) { // quando rilasci il tasto del mouse
// fai questa cosa;
}

[maxbianchi]

appena riesco a riprendermi dal trauma del risveglio provo,
intanto ti ringrazio, sei molto gentile!!! Buon W.E.