[VB6] Variare immagine al passaggio del mouse

[Artemio]

ho un Command e vorrei che al passaggio del mouse si visualizzi un immagine (e fin qui ci sono riuscito con MouseMove), ma poi vorrei anche che nel momento in cui il mouse abbandona l'area del Command, si visualizzasse un'altra immagine (ovvero quella iniziale del Command, quella impostata dalle proprietà intendo).
qualcuno mi può aiutare?

p.s. poi vorrei fare la stessa cosa anche con una picturebox... ma credo che il procedimento sia lo stesso di quello per un command giusto?
grazie in anticipo

[multijet]

io avevo risolto in questo modo:

con una chiamata api determinavo la posizione del mouse sulla form nell'evento mouse move e quando questa andava sulle coordinate x e y del bottone o della picture mi caricava l'immagine o cambiavo la proprieta' text

[Artemio]

con le API per forza?
non è possibile farlo senza?

[multijet]

A me viene in mente solo questa soluzione.

[Boolean]

non c'è modo di rilevare l'uscita da un controllo se non con l'utilizzo di un timer e di due funzioni API, nella fattispecie, la GetCursorPos e la WindowFromPoint.

se ne vuoi fare a meno devi controllare il MouseMove sul Form, ma se i controlli stanno in un frame, ad esempio, è tutto vano...

in sostanza l'utilizzo delle API è la strada migliore... che non è poi tutta questa gran difficoltà...

Boolean

[Artemio]

...se non c'e altro modo... qualcuno potrebbe farmi un codice di esempio con l'API?

[MdE2005]

L'ho scritto ora "a mano", quindi può essere migliorato molto, cmq tanto per darti un'idea (anche di come è facile usare questa funzione API):

Private Type POINTAPI
    X As Long
    Y As Long
End Type

Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long

Private Sub Form_Load()
Timer1.Enabled = True
Timer1.Interval = 1
End Sub

Private Sub Timer1_Timer()
Dim lp As POINTAPI
GetCursorPos lp
If lp.X < 100 And lp.X > 0 Or lp.Y < 200 And lp.Y > 50 Then  'la coordinata orizzontale
'è compresa tra 0 e 100, metti le coordinate del tuo command
'image1.picture = metti cosa ti pare
Else
'image1.picture = metti cosa ti pare
End If
End Sub

Il sistema di misura deve essere in pixel..

ciao

[Boolean]

il codice di MdE, può andar bene...

ma forse in questo modo hai più libertà di movimento per gestire ulteriori controlli, e poi, utilizzando come dicevo prima, la WindowFromPoint, puoi evitare di scrivere ogni volta le coordinate del controllo, anche in virtù del fatto che mi sembra di aver capito che potrebbero essere anche più di uno...

per provare il codice, metti sul form:

- 1 Timer
- 1 Pulsante con Style = Graphical
- 2 PictureBox
- 2 ImageBox con 2 immagini differenti

lascia tutti i nomi di default, e copia questo codice:

Private Declare Function GetCursorPos Lib "user32.dll" ( _
     ByRef lpPoint As POINTAPI) As Long

Private Type POINTAPI
    X As Long
    Y As Long
End Type

Private Declare Function WindowFromPoint Lib "user32.dll" ( _
     ByVal xPoint As Long, _
     ByVal yPoint As Long) As Long

Dim ActControl As Object

Private Sub Command1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Set ActControl = Command1
Timer1.Enabled = True
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Set ActControl = Picture1
Timer1.Enabled = True
End Sub

Private Sub Picture2_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Set ActControl = Picture2
Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()

Dim pt As POINTAPI

If ActControl Is Nothing Then
    Timer1.Enabled = False
    Exit Sub
End If

On Error Resume Next

GetCursorPos pt

If WindowFromPoint(pt.X, pt.Y) = ActControl.hWnd Then
    ActControl.Picture = Image1.Picture
Else
    ActControl.Picture = Image2.Picture
    Timer1.Enabled = False
    Set ActControl = Nothing
End If

End Sub

Boolean

[MdE2005]

Ciao Artemio, ti conviene usare il codice di Boolean perchè ti rende migliore la gestione (te lo avevo scritto che lo scrivevo sul momento..): forse puoi usare ciò che ti ho postato per capire come si usa quella funzione API..

ciao