Problemi con le dimensioni di un download

[mr.fifteen]

Salve a tutti
ho un problema con il download:
Ho questo script che funziona perfettamente:

<%
Dim objStream, strFileName
strFileName = Request.QueryString("file")
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Type = 1 ' adTypeBinary
objStream.Open
' objStream.LoadFromFile Server.MapPath("public/" & strFileName)
objStream.LoadFromFile Server.MapPath("public/" & strFileName)
' Istruiamo il browser sul tipo di file
Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
Response.ContentType = "application/octet-stream"
Response.BinaryWrite objStream.Read
objStream.Close
Set objStream = Nothing
%>

L'unico problema è che non mi fa fare il download di file sopra i 3,5 mb che devo fare???

[optime]

devi farlo a pezzi (letteralmente! ) cerca per il mio script di download, l'ho pubblicato diverse volte nel forum (ciao fiftyfifty )

[mr.fifteen]

OOOOOOOOOk

ho trovato questo

 <%

'8***********************************************8
' Jason Withrow - For ASP101 July 2001
' This page forces the save as dialogue to prevent
' files from being opened in the browser.
'
' jwithrow@mediaone.net
'8***********************************************8


Response.Buffer = True

Dim strFilePath, strFileSize, strFileName

' added by edc 7.1.2003
' il nome del file viene passato in una session

	If Session("FileName") = "" Then
	   Response.Redirect "default.asp"
	End If

	Dim oFso, oFile

	strFilePath = Server.MapPath(Session("FileName"))
	Set oFso = CreateObject("Scripting.FileSystemObject")
	Set oFile = oFso.GetFile(strFilePath)
	strFileName = UCase(oFile.Name)
	strFileSize = CLNG(oFile.size)
	Set oFile = Nothing
	Set oFso = Nothing

' end add

Const adTypeBinary = 1

'strFilePath = Request.QueryString("File")
'strFileSize = Request.QueryString("Size")
'strFileName = Request.QueryString("Name")

Response.Clear

'8*******************************8
' Requires MDAC 2.5 to be stable
' I recommend MDAC 2.6 or 2.7
'8*******************************8
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath

strFileType = lcase(Right(strFileName, 4))
    
	' Feel Free to Add Your Own Content-Types Here
    Select Case strFileType
        Case ".asf"
            ContentType = "video/x-ms-asf"
        Case ".avi"
            ContentType = "video/avi"
        Case ".doc"
            ContentType = "application/msword"
        Case ".zip"
            ContentType = "application/zip"
            ContentType = "application/x-zip-compressed"
        Case ".xls"
            ContentType = "application/vnd.ms-excel"
        Case ".gif"
            ContentType = "image/gif"
        Case ".jpg", "jpeg"
            ContentType = "image/jpeg"
        Case ".wav"
            ContentType = "audio/wav"
        Case ".mp3"
            ContentType = "audio/mpeg3"
        Case ".mpg", "mpeg"
            ContentType = "video/mpeg"
        Case ".rtf"
            ContentType = "application/rtf"
		Case ".htm", "html"
            ContentType = "text/html"
		Case ".asp"
            ContentType = "text/asp"
        Case Else
            'Handle All Other Files
            ContentType = "application/octet-stream"
    End Select
	
	Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
	Response.AddHeader "Content-Length", strFileSize
	' In a Perfect World, Your Client would also have UTF-8 as the default 
	' In Their Browser
	Response.Charset = "UTF-8"
	Response.ContentType = ContentType
	
	Do While Not objStream.EOS
		Response.BinaryWrite objStream.Read(1024)
		Response.Flush
	Loop

objStream.Close
Set objStream = Nothing

%>

Che sembra avere avuto la tua approvazione... ma non so se è la stessa cosa...
Cosa devo fare... lo piazzo al posto della mia vecchia pagina download.asp (quella che avevo precedentemente postato)? Devo sostituire objStream.LoadFromFile strFilePath
con objStream.LoadFromFile Server.MapPath("public/" & strFileName)??? :master:

[optime]

non hai letto il codice? c'è scritto che il nome del file va passato in session...