[VB6/VB.NET]: Connettersi ad un database Access

[xegallo]

viste le numerose richieste
breve tutorial su come connettersi ad un db access 2000 senza usare oggetti tipo l'oggetto data.

dal menù Progetto > Riferimenti

scegliere Microsoft ActiveX Data Object 2.X library

ora inserite un modulo nel vostro progetto
e copiateci dento questo codice

Option Explicit

public Cn As new ADODB.Connection
public Rs As new ADODB.Recordset

Sub connetti()
   With Cn
      .ConnectionString = "Provider = Microsoft.Jet.OleDB.4.0;" & _
                          "Data source = F:\Documents and Settings\PereGallo\Documenti\merceologia.mdb"
                          'nella prima riga si specifica il provider
                          'nella seconda il percorso al db
      .ConnectionTimeout = 5 'numero dei secondi di timeout
      .CursorLocation = adUseClient 'tipo di cursore
      .Mode = adModeShareDenyNone 'nessuna limitazione
      .Open 'apertura ricordarsi di chiuderla
   End With
   With Rs
      .ActiveConnection = Cn ' imposta a che connessione si riferisce
      .LockType = adLockOptimistic ' imposta il tipo di lock
   End With
End Sub

ora la connessione è avvenuta e avete libero accesso al database
per accedere ai dati dovete usare l'oggetto RS
per visualizzarli ho usato un datagrid

Private Sub Form_Load()
   Call Connetti
   Rs.Open "SELECT * FROM TBTessuti" ' apre il recordset leggendo tutti i campi dalla tabella
                                     ' TBTessuti
   Set DataGrid1.DataSource = Rs     'riempie la vostra griglia coi dati del recorset
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
   Rs.Close
   Cn.Close
End Sub

[Markooo]

Utile .... grazie

[ZeroOne]

a me da questo errore: impossibile assegnare segnalibri al gruppo di righe...
ed ho usato la tua stessa connessione...why?

[barney09]

NECESSARIA SP5 di Visaul Basic 6.0

[ZeroOne]

l'installato 2 mesi fa...

[xegallo]

Originariamente inviato da ZeroOne
a me da questo errore: impossibile assegnare segnalibri al gruppo di righe...
ed ho usato la tua stessa connessione...why?

mi posti la query

[ZeroOne]

Dim conn As New ADODB.Connection
Dim rs As New ADODB.Recordset

Private Sub cmdfind_Click()
conn.Open "Provider = Microsoft.Jet.OLEDB.4.0;Persist Security Info=False;Data Source =c:\programmi\officina\officina.mdb"
rs.Open "SELECT data,descrizione_lavoro FROM lavori WHERE targa_auto LIKE '" & Text1.Text & "'", conn
Set dbgrid1.DataSource = rs

End Sub

non ho impostato alcuni attributi della connessione come hai fatto te ma penso (o almeno lo spero) non sia per quelli che non va...

[xegallo]

la locazione del cursore è sul server non sul client perciò non puoi assegnarlo direttamente all'oggetto

[ZeroOne]

quindi aggiungendo alla connessione la proprietà
.CursorLocation = adUseClient 'tipo di cursore
dovrebbe andare?
grazie

[ZeroOne]

e infatti va
grazie peregallo