Il faro di BATMAN,come si puo fare,muoverlo con il mouse?

[zippomaker]

Il link e` www.zippomaker.altervista.org, ho disegnato un faro che punta sul logo, e vorrei fare l`effetto tipo faro di Batman...
cioe` far muovere (con il pulsante del mouse clikkato),il fascio di luce all`utente, che ovviemente deve esserre imperniato sul faro, e magari applicare una maschera al logo (ma quello sarebbe secondario)...

Sapete dirmi come fare?

grazie per l`ennesimo aiuto

[panta]

esegui un semplice drag sul cerchio, e poi con le drawing API disegni un fascio riempito di giallino fino alle tangenti al cerchio (che ovviamente devi calcolare)

ciao

[zippomaker]

Ho provato a fare il drag del fascio di luce,e mettere la parte sensibile, per lo spostamento,sulla parte finale del fascio di luce,il problema è che però mi si 'dragga', tutto il fascio di luce, e non sò come farlo rimanere imperniato sul proiettore dal quale parte.....

come posso bloccare solo un punto?

[panta]

Originariamente inviato da panta
esegui un semplice drag sul cerchio, e poi con le drawing API disegni un fascio riempito di giallino fino alle tangenti al cerchio (che ovviamente devi calcolare)

ciao

il cerchio è UN MovieClip... e lo dragghi

il fascio è disegnato da codice (lineTo) e pulito (clear) ad ogni frame, ed è un altro movieclip che non si muove come _x e _y, ma calcola ad ogni frame il punto di tangenza con il cerchio

[zippomaker]

ho creato un MC chiamato 'cerchio' (che sarebbe il cerchio finale del fascio luminoso), e gli ho associato:
onClipEvent (load) {
cerchio.lineTo(441,524);
cerchio.lineTo(446,666);
}

che dovrebbero essere i due punti di partenza delle 2 linee che poi dovrebbero tangere in cerchio....
....ma non succede nulla.

E' chiaro che sbaglio ma dove?

Grazie

[panta]

a parte che quello che hai fatto senza il lineStyle davanti non fa proprio niente

es lineStyle(1, 0x000000, 100) etc

poi non è che puoi calcolare a mano i due punti, ma ogni volta che il cerchio si muove e poi le linee non devono essere tracciate nel movieclip cerchio! sennò dragghi anche quelle...

ma soprattutto una domanda nasce spontanea... usi almeno flash MX? altrimenti col 5 nada...

[zippomaker]

Uso Mx, ma quando parli, mi rendo conto che piu` che usarlo,lo faccio piangere.... :maLOL:

mi mancano le basi del mestiere e soprattutto di ActionScript...

Sai dove posso guardare per vedere un`esempio di un caso attinente al mio?

grazie ancora

[zippomaker]

Per farvela breve,ero in discussione con Panta e mi ha suggerito di disegnare delle linee da codice con LineTo e LineStyle, ma credetemi in tutto il forum e in Flas-mx.it ,nei tutorial ,non sono riuscito a trovare nulla...
Non voglio fare Crossposting, vi dico solo quello che dovrei fare: disegnare 2 linee (che partono da x1,y1 e x2,y2) che toccano un cerchio (draggabile) , e farle spostare durante il drag del cerchio, ma lasciarle ancorate ai punti di partenza (x1,y1 e x2,y2)

Come posso fare?

Grazie ancora

vi segnalo il vecchio Th

http://forum.html.it/forum/showthrea...93#post6122793

[panta]

appena ho un po' di tempo (penso stasera) ti butto giù qualcosa

ciaooo

[panta]

ma eccomi qua...

allora guarda l'esempio: http://www.oaxoa.com/lab/fascio.htm

ed ecco come realizzarlo in flash MX+...

crei un movieclip e lo chiami "faro" (non come nome di istanza, proprio nella libreria) e al suo interno crei un altro movieClip chiamato come vuoi a cui però dai nome di istanza "disc_mc" (sarebbe il cerchio con il disegno)

a questo punto al primo e unico fotogramma del movieclip faro associ queste azioni:

#initclip
function Faro() {
	this.init();
}
Faro.prototype.__proto__ = MovieClip.prototype;
Faro.prototype.init = function() {
	this.createEmptyMovieClip("light_mc", 1);
	this._x = this._y = 0;
	this.r = this.disc_mc._width / 2;
	this.disc_mc.swapDepths(2);
	this.lightBaseX = -30;
	this.lightBaseY = 430;
	this.disc_mc.onMouseMove = function() {
		this._x = this._parent._xmouse;
		this._y = this._parent._ymouse;
		this._parent.drawLight();
		updateAfterEvent();
	};
};
Faro.prototype.drawLight = function() {
	var lbx = this.lightBaseX;
	var lby = this.lightBaseY;
	with (this.light_mc) {
		clear();
		beginFill(0xFFFFB5, 50);
		moveTo(lbx, lby);
            //calcolo i punti di tangenza al cerchio in base all'angolo fra essi
		var ldx = this.disc_mc._x - lbx;
		var ldy = this.disc_mc._y - lby;
		var angle = Math.atan((ldy) / (ldx));
		if (ldx >= 0) {
			angle += Math.PI;
		}
		var tx1 = this.disc_mc._x + Math.cos(angle + Math.PI / 2) * this.r;
		var ty1 = this.disc_mc._y + Math.sin(angle + Math.PI / 2) * this.r;
		var tx2 = this.disc_mc._x + Math.cos(angle - Math.PI / 2) * this.r;
		var ty2 = this.disc_mc._y + Math.sin(angle - Math.PI / 2) * this.r;
            //disegno la forma
		lineTo(tx1, ty1);
		lineTo(tx2, ty2);
		lineTo(lbx, lby);
		endFill();
	}
};
Object.registerClass("faro", Faro);
#endinitclip

vai sullo stage e vi trascini un istanza del mc "faro" posizionata dove vuoi che tanto è uguale... CTRL-Invio ed ecco l'esempio

come vedi funziona bene da qualsiasi angolo etc.

usatelo pure tranquillamente basta che mi mandate un 4esempio del risultato [eheh mi do al linkware]

ciao