Paginazione a 4 colonne

[Freedom]

Ciao,

è possibile adattare questa paginazione, paginando in quattro colonne?

objConn.ConnectionString = "Connessione" 

objConn.Open() 

strSql="select * from Table1" 
objRs.CursorLocation = 3 
objRs.CursorType = 3 
objRs.Open strSql, objConn 

contaRec = objRs.RecordCount 

for i = 0 to contaRec \2 
Response.Write "<tr>" 
Response.Write "<td>" 
objRs.MoveFirst 
objRs.Move(i) 
Response.Write objrs("id") 
Response.Write "</td>" 

if (i+(contaRec \2)) +1 < contaRec then 
objRs.MoveFirst 
objRs.Move((i+(contaRec \2)) +1) 

Response.Write "<td>" 
Response.Write objrs("id") 
Response.Write "</td>" 
else 
Response.Write "<td> </td>" 
end if 

Response.Write "</tr>" 
next

mantenendo sembre il formato:
1 | 4 | 7 | 10
2 | 5 | 8 | 11
3 | 6 | 9 | 12
.......

[santino83_11_04]

adesso a quante colonne stampa? due?

secondo me è da modificare radicalmente per portarla a 4 colonne, questa stampa solo 2 colonne controllando che non si sia arrivati all'ultimo record...

se hai capito la logica spendici sopra un paio d'ore e dovresti tirare fuori la soluzione

[Freedom]

Le ho spese ma non sono riuscito a giungere a nessuna conclusione...

Sai come devo procedere, praticamente?

[Freedom]

Come mi devo muovere? Non ho ben capito la logica ... :master:

[michele.santoro]

Originariamente inviato da Freedom
Come mi devo muovere? Non ho ben capito la logica ... :master:

Potresti prendere spunto da questo 3D tanto per cominciare

[santino83_11_04]

non fa l'ordinamento che vuole lui...

lui li vuole in ordine progressivo dalla colonna sinistra a quella destra per un totale di 4 colonne...il codice che ha ora ne stampa solo 2 se l'ho ben capito

[santino83_11_04]

come avevo detto prima, capisci la logica e ci metti 5 minuti (vabbeh, ce ne ho messi 10 lo ammetto)


provato con un numero paro/dispari di record su 4 colonne, e con un numero pari di record da 1 a 10 colonne

'******************************** SETTING
dim dbPath,num_colonne,campo,tabella
num_colonne=4
campo="Object_id"
tabella="objbase"
dbPath=server.MapPath("cms.mdb")
'******************************** END SETTING


'******************************** inizio codice

set conn=server.CreateObject("adodb.connection")
conn.open "provider=microsoft.jet.oledb.4.0;" & "data source=" & dbPath

set rs=server.CreateObject("adodb.recordset")
SQL="select " & campo & " from " & tabella & " order by " & campo & " asc"
rs.open sql,conn,3,3

dim tot_record,sott
tot_record=rs.recordcount

if tot_record mod num_colonne=0 then
	sott=0
	record_per_colonna=int(tot_record/num_colonne)
else
	sott=1
	record_per_colonna=int(tot_record/num_colonne)+1
end if

response.Flush()

'STAMPO LA TABELLA
response.write "

<table cellpadding=""0"" cellspacing=""0"" border=""1"">"


for i=0 to record_per_colonna-1

	response.write "<tr>"
	
	'stampo le colonne
	for k=0 to num_colonne-1
		rs.movefirst
		if i+(record_per_colonna*k)>(tot_record-sott) then
			response.Write "<td width=""80""></td>"
		else
			rs.move(i+(record_per_colonna*k))
			response.write "<td width=""80"">" & rs(0) & "</td>"
		end if
	next
	
	response.write "</tr>"
	
next

response.write "</table>"

rs.close: set rs=nothing
conn.close: set conn=nothing

'********************************** fine codice

fammi sapere per eventuali problemi

[Freedom]

santino Grazie davvero: FUNZIONA PERFETTAMENTE!!!!

[santino83_11_04]

prego prego, fanno 50 euro oppure 2 birre al pub tasera