differenze tra player 6 e player 8

[ghidora]

Salve a tutti,
ho scaricato dalla rete un delizioso actionscript che crea dei fiocchi di neve che cadono sullo stage.
volevo inserirlo in un mio flash.
il problema che questo actionscript funziona se lo pubblico con il player 6, lo stesso con il player 8 non funziona .
cosa può essere?
ho controllo il codice ma non c'è nessun comando non compatibile con actionscript 2.0.
se volete vi posso postare anche il codice.
grazie.

[and80]

ciao ghidora... di solito quando gli script vanno bene per AS1 e non per AS2 signifca che c'è qualche variabile utilizzata che non è stata dichiarata in precedenza (variabili numeriche di solito)

se il codice non è molto corposo, posta pure, gli darò un'occhiata

[ghidora]

ecco il codice :
quindi si tratta di dichiarazioni di variabili?


stageWidth = 550;
stageHeight = 300;
depth=0;
this.createEmptyMovieClip("snowController", 0);

snowController.createFlake = function() {
depth++;
this.attachMovie("flake", "flake"+depth, depth);
myFlake = this["flake"+depth];
myFlake._x = Math.floor(Math.random()*stageWidth);
myFlake._y = -5;
myFlake._xscale = Math.round(Math.random()*34);
myFlake._yscale = Math.round(Math.random()*34);
// ------ set vars for movement
myFlake.d = 1.7;
myFlake.a = 20;
myFlake.newX = myFlake._x;
myFlake.newY = myFlake._y;
myFlake.myXspeed = 0;
myFlake.myYspeed = 0;
myFlake.ySpeed = (myFlake._width + myFlake._height)/2;
// -------------------------------------------
myFlake.onEnterFrame = function () {
if (!Math.floor(Math.random()*8)) {
this.xSpeed = Math.round(Math.random()*10)-5;
}
this.newX += this.xSpeed;
this.newY += this.ySpeed;
if (this._y > stageHeight) {this.removeMovieClip();}
this.myXspeed = ((this._x-this.newX)/this.a+this.myXspeed)/this.d;
if(this._name=="flake1") trace(this.myXspeed);
// this is just movement code to make is move smoother
this.myYspeed = ((this._y-this.newY)/this.a+this.myYspeed)/this.d;
this._x -= this.myXspeed;

this._y -= this.myYspeed;
}
}
// ----------------
snowController.onEnterFrame = function () {
if (!Math.floor(Math.random()*10)) {
this.createFlake();

}
}

[and80]

ho letto lo script e sembra che tutte le variabili siano state inizializzate prima del loro utilizzo, può darsi che ci sia qualcosa che non ho visto, purtroppo non posso provare lo script in questo momento perchè non ho flash a disposizione... appena posso ti faccio sapere ok?!

[ghidora]

sto dando un occhiata pure io al codice e sembra che la variabile myFlake.newX non venga poi riconosciuta su myFlake.onEnterFrame.
Cmq grazie per l'interessamento.

[and80]

Originariamente inviato da ghidora
sto dando un occhiata pure io al codice e sembra che la variabile myFlake.newX non venga poi riconosciuta su myFlake.onEnterFrame.
Cmq grazie per l'interessamento.

è vero! bravo il problema è che myFlake.xSpeed esiste solo se ... quindi se non esiste succede il macello... allora basta che poco prima di questa riga

myFlake.ySpeed = (myFlake._width + myFlake._height)/2;

tu metta

myFlake.xSpeed = 0;

e tutto dovrebbe tornare apposto (salvo che non ci siano altre variabili "giocate" in quel modo)