Problema invio email in "segnala notizia ad un amico"

**Roby140569** · 04-07-2007, 13:18

Ho creato uno script per segnalare una notizia di un sito "ad un amico"... funzionava, ma devo aver fatto qualche modifica e non mi funziona più, nel senso che non parte l'email.

Questo è il form:

codice:

<form method="post" name="emailCDO">
E-mail del tuo amico:
<input name="e-mail">

Tuo nome:
<input name="fromName" >

Tua e-mail:
<input name="from">

Testo:
<textarea name="Text" rows="4" cols="30" textarea>


<input type="hidden" name="url" value="<%=Request.ServerVariables("HTTP_REFERER")%>">
<input type="submit" value="Invia">
</form>

Questo è il codice per inviare l'email:

codice:

<%

if len(Request.Form)>0 then
Set objMail = Server.CreateObject("CDONTS.NewMail")
strFrom = request("fromName") & "<" &_
request("from") &">"
strUrl = request("url")
link = strUrl
strTxt = request("Text") & VbcrLf & _
"" & strUrl	
objMail.From = strFrom
objMail.Body = strTxt
objMail.To = Request("e-mail")
objMail.Subject = "Ti segnalo questa notizia"
objMail.Send
set objMail = nothing
	
Response.Write("<p align='center'>SEGNALAZIONE INVIATA CON SUCCESSO</p>
")
Response.Write("<p align='center'>Per tornare alla news che stavi leggendo, clicca <a href=")
Response.Write(link)
Response.Write(">qui</a>.</p>")
		
end if

%>

Cosa sbaglio?

**fraude** · 04-07-2007, 13:41

Stai provando direttamente sul server o in localhost?

**Roby140569** · 04-07-2007, 13:50

Sul server.

**fraude** · 04-07-2007, 13:52

hai verificato che il componente CDONTS che utilizzi per l'invio email sia presente sul server?

<html>

codice:

<head>
<title>Server Component Checker</title>
</head>
<body>
<%

	Dim comList(54)
		comList(0) = Array( "AB Mailer","ABMailer.Mailman" )
		comList(1) = Array( "ABC Upload","ABCUpload4.XForm" )
		comList(2) = Array( "ActiveFile","ActiveFile.Post" )
		comList(3) = Array( "ActiveX Data Object","ADODB.Connection" )
		comList(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
		comList(5) = Array( "ASP HTTP","AspHTTP.Conn" )
		comList(6) = Array( "ASP Image","AspImage.Image" )
		comList(7) = Array( "ASP Mail","SMTPsvg.Mailer" )
		comList(8) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
		comList(9) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
		comList(10) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
		comList(11) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
		comList(12) = Array( "ASP Tear","SOFTWING.ASPtear" )
		comList(13) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
		comList(14) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
		comList(15) = Array( "ASPEmail","Persits.MailSender" )
		comList(16) = Array( "ASPSoft NT Object","ASPSoft.NT" )
		comList(17) = Array( "ASPSoft Upload","ASPSoft.Upload" )
		comList(18) = Array( "CDONTS","CDONTS.NewMail" )
		comList(19) = Array( "CDOSYS","CDO.Message" )
		comList(20) = Array( "Chestysoft Image","csImageFile.Manage" )
		comList(21) = Array( "Chestysoft Upload","csASPUpload.Process" )
		comList(22) = Array( "Chili!Mail","CDONTS.NewMail" )
		comList(23) = Array( "Dimac JMail","JMail.Message" )
		comList(24) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
		comList(25) = Array( "dkQMail","dkQmail.Qmail" )
		comList(26) = Array( "Dundas Mailer","Dundas.Mailer" )
		comList(27) = Array( "Dundas Upload","Dundas.Upload.2" )
		comList(28) = Array( "Dynu Encrypt","Dynu.Encrypt" )
		comList(29) = Array( "Dynu HTTP","Dynu.HTTP" )
		comList(30) = Array( "Dynu Mail","Dynu.Email" )
		comList(31) = Array( "Dynu Upload","Dynu.Upload" )
		comList(32) = Array( "Dynu WhoIs","Dynu.Whois" )
		comList(33) = Array( "Easy Mail","EasyMail.SMTP.5" )
		comList(34) = Array( "Emailtoolbox","ArclabEmailToolBox.Mailer" )
		comList(35) = Array( "File System Object","Scripting.FileSystemObject" )
		comList(36) = Array( "Geocel.Mailer","GeoCel" )
		comList(37) = Array( "IISMail","iismail.iismail.1" )
		comList(38) = Array( "JMail","Jmail.smtpmail" )
		comList(39) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
		comList(40) = Array( "Last Mod","LastMod.FileObj" )
		comList(41) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
		comList(42) = Array( "Persits ASP JPEG","Persits.Jpeg" )
		comList(43) = Array( "Persits ASPEmail","Persits.MailSender" )
		comList(44) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
		comList(45) = Array( "Persits File Upload","Persits.Upload.1" )
		comList(46) = Array( "SmartMail","aspSmartMail.SmartMail" )
		comList(47) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
		comList(48) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
		comList(49) = Array( "Image Size", "ImgSize.Check" )
		comList(50) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
		comList(51) = Array( "Grafici Excel", "OWC.Chart" )
		comList(52) = Array( "ADODB Stream", "ADODB.Stream" )
		comList(53) = Array( "VSEmail1.0","VSEmail.SMTPSendMail" )
		comList(54) = Array( "VSEmail2.0","VSEmail.SMTPSendMailEx" )


	Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=""3"" cellspacing=""0"" border=""1"" bordercolor=""#000000"" align=""center"" width=""300"">" & vbNewLine
		strTxt = strTxt & "<tr><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">COMPONENTE</font></td><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">STATUS</font></td></tr>"
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=""150""><font face=""tahoma"" size=""2"" color=""#000000"">" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=""left""><font face=""tahoma"" size=""2"" color=""#000000"">[  "
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<font face=""tahoma"" size=""2"" color=""blue"">Installato</font>"
				Avail = Avail + 1
			Else
				strTxt = strTxt & "Non Installato</font>"
			End If
			strTxt = strTxt & "  <font face=""tahoma"" size=""2"" color=""#000000"">]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font face=""tahoma"" size=""2"" color=""blue"">" & Avail & "</font><font face=""tahoma"" size=""2"" color=""#000000""> su "
	strTxt = strTxt & UBound( comList ) + 1 & " componenti installati.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

<p align="center">
	<font face="Tahoma" size="2">Server Component Checker
Direttamente dal forum di html.it</font>
</p>
</body>
</html>

**Roby140569** · 04-07-2007, 16:32

Questi sono i componenti installati:
1. ActiveX Data Object
2. CDONTS
3. CDOSYS
4. Chili!Mail
5. File System Object
6. Microsoft XML Engine
7. Microsoft XML HTTP
8. ADODB Stream

Ci sono, sia CDONTS sia CDOSYS, quindi la mia email dovrebbe partire, no?

**Roby_72** · 04-07-2007, 16:42

Nel .from prova ad inserire una email configurata nel dominio che spedisce.

Roby

**Roby140569** · 04-07-2007, 16:58

Sì, così funziona... quindi?

**Roby_72** · 04-07-2007, 17:01

Quindi cosa? Spedisci con l'indirizzo email configurato e se ti serve quello inserito nel form di inserimento mettilo nel corpo dell'email.

Roby

**Roby140569** · 04-07-2007, 17:05

Sarebbe meglio se l'email venisse spedita facendo apparire sul From l'indirizzo che l'utente scrive nel form, non un indirizzo sul dominio.
Prima mi funzionava prendendo l'indirizzo email da .From, adesso non me lo prende...

**Roby_72** · 04-07-2007, 17:06

L'avranno impedito, correttamente secondo me.

Roby

Discussione: Problema invio email in "segnala notizia ad un amico"

Strumenti discussione

Ricerca discussione

Visualizza

Problema invio email in "segnala notizia ad un amico"

Permessi di invio