aiuto su banner che pesca da un db

[danielix05]

ciao,
qualcuno sa darmi una dritta su come realizzare un banner che contenga 4 piccole immagini che cambiano?
la fonte sarebbe una cartella con un centinaio di piccole foto.

grz daniele.

[Wama]

le immagini vengono pescate da un db o da una cartella?
il pescaggio delle immagini è casuale o secondo criteri definiti?

[danielix05]

ciao,
le immagini dovrebbero essere pescate da una cartella in maniera casuale. l'importante che cambino magari una dopo qualche secondo.
aspetto

[Wama]

eccomi...

http://www.tutorial-web.com/asp/fso/...property=Files

qui trovi del codice che ti permette di vedere i file che sono presenti in una determinata cartella (che ovviamente imposti tu con il nome e il percorso di quella che ti interessa)

una volta che conosci i nomi dei file contenuti si crea uno script che permette di farne visualizzare uno alla vota ogni tot secondi.

ti posso consigliare di iniziare a farti comparire nella pagina i nomi di tutte le immagini presenti nella cartella.
poi fai una funzione che le pesca in modo casuale.
poi aggiungi una "scadenza" alla funzione in modo che ogni tot secondi riparta o mostri l'immagine successiva.
ti posso aiutare con un pò di codice, ma inizia a provare tu.
non lo faccio per cattiveria, ma se ti do qualcosa di già pronto che divertimento c'è...?

fammi sapere
bacio

[EmTmE]

Originariamente inviato da danielix05
ciao,
le immagini dovrebbero essere pescate da una cartella in maniera casuale. l'importante che cambino magari una dopo qualche secondo.
aspetto

se riesci a farlo posta che sarebbe un sacco utile anche a me ...

[danielix05]

Ciao,
dalla scorsa settimana, con pazienza, (sai non sono un programmatore ma un ricercatore di senso :-) nel senso che mi va di imparare abbastanza, anche cose che nn appartengono alla mia preparazione ... sto cercando di seguire il tuo consiglio che apprezzo sinceramente.

ora ho trovato questo articolo di microsoft http://support.microsoft.com/kb/247745/en-us
il quale sembra fare a caso nostro.

ho implementato le pagine come descritto in http://www.viagginelsalento.it/artec...randomtest.asp
ma mi restituisce una sola immagine come se non trovasse le altre nella cartella /immagini/ che ne contiene 4 in tutto.

why?

[Wama]

se hai seguito alla lettera l'esempio di microsoft posta il codice del file
RandomImage.inc
l'errore se c'è è li

[Wama]

fai anche un'altra prova.
dal file RandomImage.inc prova a togliere la riga
On Error Resume Next
(dovrebbe essere la seconda, o comunque all'inizio del file)
e se ti mostra qualche errore posta l'errore.

[EmTmE]

ho fatto la prova come indicato da ms ed ha funzionato al primo colpo ...
a questo punto mi sorge una domanda ...
sei sicuro che sia una "funzione autorizzata" sul tuo spazio web ?
magari è un optional e dal tuo fornitore non è stato attivato

[danielix05]

grazie ragazzi,

io sono su aruba. di quale funzione dovrei chiedere?

il codice di random.inc è

<%
  Function RandomImage(strPath,strDefault)
    On Error Resume Next
    Randomize Timer

    ' declare all variables
    Dim objFSO, objFolder, objFiles, objFile
    Dim strFiles, strImages, strPhysical, strFile

    ' this constant has the names of valid image file name
    ' extensions and can be modified for more image types
    Const strValid = ".gif.jpg.png"

    ' make sure we have a trailing slash in the path
    If Right(strPath,1) <> Chr(47) Then strPath = strPath & Chr(47)
    ' get the physical path of the folder
    strPhysical = Server.MapPath(strPath)
    ' get a File System Object
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
    ' create a folder object
    Set objFolder = objFSO.GetFolder(strPhysical)
    ' get the files collection
    Set objFiles = objFolder.Files

    ' enumerate the files collection looking for images
    For Each objFile in objFiles
      strFile = LCase(objFile.Name)
      If Instr(strValid,Right(strFile,4)) Then
        ' add vaild images to a string of image names
        strFiles = strFiles & strFile & vbTab
      End If
    Next

    ' split the image names into an array
    strImages = Split(strFiles,vbTab)
    
    ' if we have an array...
    If UBound(strImages) > 1 Then
      ' get a random name
      RandomImage = strPath & strImages(Int(Rnd(1)*UBound(strImages)))
    Else
      ' otherwise return the default
      RandomImage = strDefault
    End If

  End Function
%>

togliendo la seconda riga "On Error Resume Next"
succede questo errore

Microsoft VBScript runtime error '800a004c'

Path not found

RandomImage.inc, line 21

la riga è quella che contiene Set objFolder = objFSO.GetFolder(strPhysical)


attendo, grazie ancora. daniele.