[Paginazione] Due articoli su una riga

**Spyfil** · 19-06-2008, 09:43

Ciao,
so che è una domanda da pivello. Ma finora non mi ero mai trovato ad affrontare il problema.
Praticamente vorrei mostrare 2 record sulla stessa riga di una tabella.

E quando ho articoli pari tutto funziona. Ovviamente con articoli dispari va in errore perchè mi trova che sono finiti i record.

Di solito sulle gallerie di immagini uso Horizontal Looper ma in questo caso dove ho una riga di tabella con due colonne e su ogni colonna foto e nome articolo non credo sia l'ideale.

Insomma tagliando corto. C'è il modo di mettere 2 articoli (quindi 2 record) nella stessa riga senza che la pagina vada in errore quando gli articoli sono dispari?

**optime** · 19-06-2008, 09:45

chiediti ad ogni .movenext se sei arrivato a fine file (.eof)

that easy!

**Spyfil** · 19-06-2008, 09:59

Ma ci ho provato.. è questo che mi PUZZA!!
Guarda..

codice:

if not rs.eof or not rs.bot then
   while not rs.eof
        MOSTRO ARTICOLO 1
        rs.movenext
        MOSTRO ARTICOLO 2
   rs.movenext
   wend
end if

dove lo metto il controllo?

**Spyfil** · 19-06-2008, 10:31

Sembrava così facile.. ma non ho ancora risolto.. Dai datemi una manina..
UP

**Spyfil** · 19-06-2008, 10:52

Per chi è interessato ho risolto con questo script:

codice:

<%@LANGUAGE = VBScript%>
<%
    ' DEFINISCO LE VARIABILI CHE MI SERVONO PER L'APPLICAZIONE
    Dim sc, cn, rs, contatore

    ' DEFINISCO LA STRINGA DI CONNESSIONE
    sc = ""
    sc = sc & "driver={Microsoft Access Driver (*.mdb)};dbq="
    sc = sc & Server.MapPath("database.mdb")

    ' IMPOSTO LA CONNESSIONE EDIL RECORDSET
    Set cn = Server.CreateObject("ADODB.Connection")
    Set rs = Server.CreateObject("ADODB.Recordset")

    ' APRO LA CONNESSIONE COL DATABASE
    cn.Open sc
%>

<html>
<head>
<title>Paginazione a colonne sui record di un db in ASP</title>
</head>
<body>

<table border="1"><tr>
<%
    ' IMPOSTO A 0 IL CONTATORE
    contatore = 0
    ' APRO IL RECORDSET
    rs.Open "SELECT * FROM prodotti ORDER BY nome ASC", cn, 1
    ' ESEGUO IL CICLO
    While rs.EOF = False
        ' IMPOSTO LA PAGINAZIONE A 2 COLONNE ED N RIGHE
        ' IN FUNZIONE DEL NUMERO DI RECORD PRESENTI NEL DB
        If contatore = 2 Then
            contatore = 0
            Response.Write "</tr><tr>"
        End If
%>
    <td><%=rs("nome")%></td>
<%
        rs.MoveNext
        ' INCREMENTO IL VALORE DEL CONTATORE
        contatore = contatore + 1
    Wend
    rs.Close
%>
</tr></table>

</body>
</html>
<%
    ' UN PO DI PULIZIA...
    Set rs = Nothing
    cn.Close
    Set cn = Nothing
%>

ovviamente adattato al mio caso..

**optime** · 19-06-2008, 12:58

codice:

rs.movefirst
do
   IF RS.EOF THEN EXIT DO
        MOSTRO ARTICOLO 1
        rs.movenext
   IF RS.EOF THEN EXIT DO
        MOSTRO ARTICOLO 2
   rs.movenext
   IF RS.EOF THEN EXIT DO
LOOP

Discussione: [Paginazione] Due articoli su una riga

Strumenti discussione

Ricerca discussione

Visualizza

[Paginazione] Due articoli su una riga

Permessi di invio