AS3 - Problema con rotazione ellittica e gestione della profondità

[Ciamiz]

Ciao a tutti, scusate se il titolo non è molto chiaro, ma mi sono appena svegliato e non mi veniva niente di meglio xD!

Comunque, ho realizzato questo "menu" rotante, che ora per testarlo ha tutti i bottoni uguali.

Questo menu rotea su un'ellissi, ma non riesco a gestire la profondità dell'ultimo item del menu.
Se fate fare almeno un giro al menu, vi accorgerete che ad un certo punto c'è una clip che si comporta in modo scorretto.

Per aiutare nella comprensione, vi posto il codice:

// Imposto il centro dell'ellissi
var centroX:Number = this.width / 2;
var centroY:Number = this.height * 0.6;

var mousePos = ( ( this.mouseX - centroX ) / 100 );
var angle:Number = menu.length();

function on_enter_frame(e:Event):void
{
	if ( this.mouseY < this.movAreaSensibile.y )
	{
		mousePos += 0.2;
	}
	else
	{
		if ( ( ( this.movAreaSensibile.mouseX - centroX ) / 100 ) > 2 )
		{
			mousePos += 2;
		}
		else if ( ( ( this.movAreaSensibile.mouseX - centroX ) / 100 ) < -2 )
		{
			mousePos -= 2;
		}
		else
		{
			mousePos += ( ( this.movAreaSensibile.mouseX - centroX ) / 100 );
		}
	}
	
	for ( var i:Number = 0; i < playerini.length(); i++ )
	{
		var depth:Number = ( ( mousePos + ( (360 / angle) * i ) ) * Math.PI ) / 180;
		
		menu.getItemByIndex(i).x = centroX - ( Math.sin( depth ) * 430 ) - (menu.getItemByIndex(i).width / 2);
		menu.getItemByIndex(i).y = centroY + ( Math.cos( depth ) * 130 );
		menu.getItemByIndex(i).scaleX = ((100 + ( Math.cos( depth ) * 50 )) / 100);
		menu.getItemByIndex(i).scaleY = ((100 + ( Math.cos( depth ) * 50 )) / 100);
		
		if ( i != (menu.length() - 1) )
		{
			// gira in senso orario
			if ( Math.sin(depth) > 0 )
			{
				this.movPlaylist.setChildIndex(menu.getItemByIndex(i), 0);
			}
			// gira in senso anti-orario
			else
			{
				this.movPlaylist.setChildIndex(menu.getItemByIndex(i), this.movPlaylist.numChildren - 1);
			}
		}
	}
	
}

Grazie a tutti in anticipo! Ciao!
Ciamiz

[and80]

Questa è la stessa cosa ma con una funzione in più "arrange()" che gestisce le profondità a seconda della posizione:

var data:Object = {numOfItems:20, radiusX:275, radiusY:80, centerX:int(stage.stageWidth * 0.5), centerY:int(stage.stageHeight * 0.5), speed:0.05};
var items:Array = [];
for (var i:uint=0; i<data.numOfItems; i++) {
    items.push(addChild(new Item()) as Item);
    items[i].name = "target"+i;
    items[i].ang = i * (2 * Math.PI) / data.numOfItems;
    items[i].filters = [new GlowFilter(0xFFFF80, 0.5, 8.0, 8.0, 2, 2)];
    items[i].addEventListener(Event.ENTER_FRAME, enterframe);
}
function enterframe (evt:Event):void {
    var t:Item = evt.target as Item;
    t.x = data.radiusX * Math.cos(t.ang) + data.centerX;
    t.y = data.radiusY * Math.sin(t.ang) + data.centerY;
    t.ang += data.speed;
    t.scaleX = t.scaleY = t.y / (data.radiusY + data.centerY);
    arrange();
}
function arrange():void {
    items.sortOn("y", Array.NUMERIC);
    var i:int = items.length;
    while(i--){
        if (getChildIndex(items[i]) != i) {
            setChildIndex(items[i], i);
        }
    }
}
stage.addEventListener(MouseEvent.MOUSE_MOVE, function (evt:MouseEvent):void { data.speed = (mouseX-data.centerX)/4000; }); 

Nel mio esempio c'è un clip concatenato come classe Item, in libreria.

[Ciamiz]

Ok innanzitutto grazie per la risposta.

E poi... grazie per il suggerimento! Ho provato, e con qualche accorgimento ha funzionato anche per me!

Grazie Mille!
Ciao!

Ciamiz

[daryl74]

Sto provando a riadattare il codice postato da AND80 ma ho dei problemi in compilazione con l'elemento "Item".

Qualcuno può aiutarmi ?

DaryL74

[robertopd]

Potresti provare a postare l'errore che ti esce quando esporti il filmato. Così possiamo capire meglio cosa c'è che non va...

[and80]

Considera che "Item" può essere una classe esterna o un elemento nella libreria che era già presente nel progetto di Ciamiz. Quindi la dovresti sostituire con un altro elemento.

[daryl74]

Grazie AND80, ho creato in libreria un clip contenente un quadrato nero dandogli come classe "Item"e il codice funzione. Adesso devo solo capire come caricare dentro i clip "Item" delle immagini esterne leggendone i nomi da un XML.

Grazie ancora