Lista degli elementi sul livello e sullo stage

[wackyrace]

Ciao a tutti,
mi servirebbe un aiuto per listare in Actionscript 3 gli oggetti che ci sono sullo stage e su un particolare livello.

Ho travato qualcosa del tipo:

for (i in _root)
{
if (typeof(eval(i)) == "movieclip")
{
trace(eval(i)._name);
}
}

ma non funziona con actionscript 3. Ho provato a modificare in questo modo

for(i in this)
{
trace(i);
}
così non da errori ma non fa niente, non entra nel ciclo for.

[wackyrace]

Ciao ho provato per sicurezza con actionscript 2 e questo codice funziona perfettamente.

for (var prop in _root) {
if(typeof(_root[prop]) == "movieclip"){
_root[prop]._visible = false;
trace(_root[prop]._name);
}
}

Vorrei riuscire a tradurlo in actionscript3

il debug di flash dice innanzitutto che _root non è più usato ed è stato sostituito da Stage.
Ho provato quindi:

for (var prop in Stage){
trace("entra");
}
ma non entra nel ciclo. Ho provato, senza successo, a sostituire _root con: this, Stage, Stage.root.

Grazie a tutti

[and80]

Devi affidarti ad un ciclo diverso, usare un while o un for e scorrere tutti i clip presenti secondo l'indice

for (var i:uint=0; i<this.numChildren; i++) {
    if (this.getChildAt(i) is MovieClip) {
        trace(this.getChildAt(i));
    }
} 

Io l'ho tradotta in funzione "getChildren":

function getChildren (t:DisplayObjectContainer, c:Class = null):Array {
    var a:Array = [];
    for (var i:uint=0; i<t.numChildren; i++) {
        if (c) {
            if (t.getChildAt(i) is c) {
                a.push(t.getChildAt(i));
            }
        } else {
            a.push(t.getChildAt(i));
        }
    }
    return a;
} 

Il secondo parametro è opzionale e se viene omesso l'array risultante sarà composto da ogni elemento presente all'interno del contenitore di riferimento, altrimenti risulteranno presenti solo gli elementi visuali della classe specificata.

trace(getChildren(this)); // visualizzo tutti gli elementi su this
trace(getChildren(this), MovieClip); // visualizzo solo gli elementi MovieClip su this
trace(getChildren(this), SimpleButton); // visualizzo solo gli elementi SimpleButton su this 

Per usare root devi trasformarlo in "MovieClip" perchè come proprietà risulta essere un "DisplayObject" e di conseguenza non potrebbe avere dei children

trace(getChildren(MovieClip(root))); 

Stage restituirà solo un child, ossia la timeline principale

trace(getChildren(stage)); // restituisce: [object MainTimeline] 

[wackyrace]

che dire.....
Funziona tutto perfettamente..

Complimenti per l'ottimo post!
E Grazie, erano due giorni che cercavo documentazione.