Download forzato pdf

[slay]

ciao a tutti uso questo codice per forzare file pdf:

Dim download, file 
        file = ""&b_rs_articoli("nome_file_pdf")&"" 

        ' Creo l'oggetto ADODB.Stream 
        Set download = Server.CreateObject("ADODB.Stream") 

        ' Apro la connessione e carico il file 
        download.Type = 1 
        download.Open 
        download.LoadFromFile Server.MapPath(file) 

        ' Aggiungo le intestazioni del tipo di file 
        Response.AddHeader "Content-Disposition", "attachment; filename=" & file 
        Response.ContentType = "application/octet-stream" 
        Response.BinaryWrite download.read 

        ' Un po di pulizia... 
        download.Close 
        Set download = Nothing 

Il tutto funziona bene .. il problema è che per qualche file non mi fa il download per quelli più grossi .. volevo sapere c'è un limite alla grandezza del pdf che non devo superare?
Come potrei risolvere la cosa?

[optime]

cerca adosend in questo forum

[slay]

ok risolto .. grazie come sempre

per chi volesse ecco il codice usato..

Session.Timeout = 200
        '8***********************************************8
        ' Jason Withrow - For ASP101 July 2001
        ' This page forces the save as dialogue to prevent
        ' files from being opened in the browser.
        '
        ' [email]jwithrow@mediaone.net[/email]
        '8***********************************************8


        Response.Buffer = True

        Dim strFilePath, strFileSize, strFileName,objStream,strFileType,ContentType


        Dim oFso, oFile
        Session("FileName")="nome del file da scaricare"
        strFilePath = Server.MapPath(Session("FileName"))
        Set oFso = CreateObject("Scripting.FileSystemObject")
        Set oFile = oFso.GetFile(strFilePath)
        strFileName = UCase(oFile.Name)
        strFileSize = CLNG(oFile.size)
        Set oFile = Nothing
        Set oFso = Nothing

        ' end add

        Const adTypeBinary = 1

        'strFilePath = Request.QueryString("File")
        'strFileSize = Request.QueryString("Size")
        'strFileName = Request.QueryString("Name")

        Response.Clear

        '8*******************************8
        ' Requires MDAC 2.5 to be stable
        ' I recommend MDAC 2.6 or 2.7
        '8*******************************8
        Set objStream = Server.CreateObject("ADODB.Stream")
        objStream.Open
        objStream.Type = adTypeBinary
        objStream.LoadFromFile strFilePath

        strFileType = lcase(Right(strFileName, 4))
    
    ' Feel Free to Add Your Own Content-Types Here
    Select Case strFileType
        Case ".asf"
            ContentType = "video/x-ms-asf"
        Case ".avi"
            ContentType = "video/avi"
        Case ".doc"
            ContentType = "application/msword"
        Case ".zip"
            ContentType = "application/zip"
            ContentType = "application/x-zip-compressed"
        Case ".xls"
            ContentType = "application/vnd.ms-excel"
        Case ".gif"
            ContentType = "image/gif"
        Case ".jpg", "jpeg"
            ContentType = "image/jpeg"
        Case ".wav"
            ContentType = "audio/wav"
        Case ".mp3"
            ContentType = "audio/mpeg3"
        Case ".mpg", "mpeg"
            ContentType = "video/mpeg"
        Case ".rtf"
            ContentType = "application/rtf"
        Case ".htm", "html"
            ContentType = "text/html"
        Case ".asp"
            ContentType = "text/asp"
        Case Else
            'Handle All Other Files
            ContentType = "application/octet-stream"
    End Select
    
    Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
    Response.AddHeader "Content-Length", strFileSize
    ' In a Perfect World, Your Client would also have UTF-8 as the default 
    ' In Their Browser
    Response.Charset = "UTF-8"
    Response.ContentType = ContentType
    
    Do While Not objStream.EOS
        Response.BinaryWrite objStream.Read(8192)    '    1024*8
        Response.Flush
    Loop

    objStream.Close
    Set objStream = Nothing 

[gigino10]

Scusate, tutta questa roba in quale parte del codice va inserito?

[optime]

Originariamente inviato da gigino10
Scusate, tutta questa roba in quale parte del codice va inserito?

dove c'è il download...

[gigino10]

Grazie mille!!! Ho risolto. Ho messo un link che apre un pagina vuota nella quale ho inserito tutto il codice postato da slay. Fuonziona benissimo

[optime]

optime!