Grafici A Barre Doppie Con Owc

[abbath]

Ciao ragazzi... mi chiedevo se è possibile usare il grafico creato tramite gli office web components (codice 48) a barre doppie ovvero mettere due valori sulla stessa barra in modo che possa confrontare sulla stessa due valori diversi. Mi sono spiegato? VVoVe:

[Peter_Pan]

certo

<% 

	'Creiamo l'oggetto 
	Set ChartObj = Server.CreateObject("OWC10.ChartSpace") 

	Set ChartConsts = ChartObj.Constants 
	set NewChart = ChartObj.Charts.Add

	'Settiamo il tipo di grafico va da 0 a 65 circa con dei buchi
	NewChart.Type = 47  

	'Setto il colore di sfondo 
	NewChart.PlotArea.Interior.Color = "#A4B5F6" 

	'Titolo del grafico
	NewChart.HasTitle = True 
	ChartObj.HasChartSpaceTitle = True 
	ChartObj.ChartSpaceTitle.Caption = "Titolo Principale" 
	ChartObj.ChartSpaceTitle.Font.Bold = True 

	'Sotto titolo
	NewChart.Title.Caption = "Questo e' il sotto-titolo"

	'Creiamo gli array che conterranno i dati da passare all'oggetto e necessari a creare il grafico 
	ReDim ARR_VISITE(2)
	ReDim ARR_VISITE1(2) 
	ReDim ARR_GIORNI(2) 

	' ASSE Y 
	ARR_VISITE(0)=10.8 
	ARR_VISITE(1)=34.98 
	ARR_VISITE(2)=20.98 

	' ASSE Y1 
	ARR_VISITE1(0)=15.8 
	ARR_VISITE1(1)=10.98 
	ARR_VISITE1(2)=40.98

	' ASSE X 
	ARR_GIORNI(0)="pippo" 
	ARR_GIORNI(1)="pluto" 
	ARR_GIORNI(2)="paperino" 

	'Passiamo i valori al grafico 
	NewChart.HasLegend = True 'Attivazione della Legenda
	'Creazione delle due serie
	Set Serie = NewChart.SeriesCollection.Add 'Prima colonna
	Set Serie1 = NewChart.SeriesCollection.Add 'Seconda colonna

	NewChart.SeriesCollection(0).Caption = "Uniche" 'scritte della legenda x la prima serie
	NewChart.SeriesCollection(1).Caption = "Totali" 'scritte della legenda x la seconda serie 

	Serie.SetData ChartConsts.chDimCategories, ChartConsts.chDataLiteral, ARR_GIORNI 
	
	Serie.SetData ChartConsts.chDimValues, ChartConsts.chDataLiteral, ARR_VISITE 
	Serie1.SetData ChartConsts.chDimValues, ChartConsts.chDataLiteral, ARR_VISITE1 

	'Settiamo il path dell'immagine che verrà creata 
	ImagePath=server.mappath("report.gif") 
	'Salviamo l'immagine 
	ChartObj.ExportPicture ImagePath,"gif", 500, 400 
	Response.Write("[img]report.gif[/img]")

	set oChart=nothing 

%>

[abbath]

MITICOOOOOOOOOOOOOOOOOOOOOOOOOO