grafici e ASP

[alexinside83]

ciao a tutti...
volevo sapere se con ASP (e magari css) e possibile costruire grafici (per esempio densità di clienti per regione)

grazie a tutti.

ale

[morphy79]

installi l'oggetto OWC ( è una libreria di office ) poi con questo codice ti puoi reliazzare tutti i grafici che vuoi, come quelli di excel !!!

    
			<%
			'Creiamo l'oggetto
			Set ChartObj = Server.CreateObject("OWC10.ChartSpace")

			Set ChartConsts = ChartObj.Constants
			set NewChart = ChartObj.Charts.Add

			'Settiamo il tipo di grafico
			NewChart.Type = 15

			' ESECUZIONE QUERY SQL PER LE HITS

			execStr = "Exec HitGiorno '" & gruppo & "','" & CG.DateUsr2Dbf(left(dta_ini,10)) & "','" & CG.DateUsr2Dbf(left(dta_fin,10)) & "'"


			Set rs = conn.Execute (execStr)
			if not rs.EOF and not rs.BOF then

				'INIZIO CICLO
				index = 0
				ReDim ARR_HITS(-1)
				ReDim ARR_GIORNI(-1)

				Do while not RS.EOF
	
					ReDim Preserve ARR_HITS(UBound(ARR_HITS) + 1)
					ReDim Preserve ARR_GIORNI(UBound(ARR_GIORNI) + 1)

					ARR_HITS(index) = rs("Hits")

					ARR_GIORNI(index) = Mid(rs("Date"),5,2) & "-" & Mid(rs("Date"),7,2) & "-" & Mid(rs("Date"),3,2)
		
					rs.MoveNext
					index=index+1
				Loop
				'FINE CICLO

			else

			end if
			RS.Close
			Set RS = Nothing 	

			'Passiamo i valori al grafico
			Set Serie = NewChart.SeriesCollection.Add

			Serie.SetData ChartConsts.chDimCategories, ChartConsts.chDataLiteral, ARR_GIORNI

			Serie.SetData ChartConsts.chDimValues, ChartConsts.chDataLiteral, ARR_HITS
			

			'set up some additional properties
			'add and format the chart title
			
			NewChart.HasTitle = True
			NewChart.Border.Color = "Red"	' colore del bordo della tabella

			'NewChart.HasLegend = True       ' visualizza o meno la legenda
			'NewChart.SeriesCollection(0).Caption = "PROVE"   ' testo della legenda

			NewChart.Title.Caption = "Grafico riepilogo Hit per giorno ( tutte le date )"
			set objFont = NewChart.Title.Font
			objFont.Name = "Tahoma"
			objFont.Size = 10
			objFont.Bold = True

			'add and format a title to the category axis
			set objAxis = NewChart.Axes(ChartConsts.chAxisPositionBottom)
			objAxis.HasTitle = True
			objAxis.Title.Caption = "Date"
			set objFont = objAxis.Title.Font
			objFont.Name = "Tahoma"
			objFont.Size = 8
			objFont.Bold = True

			'add and format a title to the value axis
			set objAxis = NewChart.Axes(ChartConsts.chAxisPositionLeft)
			'objAxis.NumberFormat = "." 

			objAxis.HasTitle = True
			objAxis.Title.Caption = "Hits"
			set objFont = objAxis.Title.Font
			objFont.Name = "Tahoma"
			objFont.Size = 8
			objFont.Bold = True
			objFont.Color = "#FF0000"
	
			'NewChart.SeriesCollection(0).Interior.Color = "red"		' per grafico istogramma
			NewChart.SeriesCollection(0).Line.Color = "#5FD9F6"	' per grafico a linee		
			
			'Settiamo il path dell'immagine che verrà creata
			ImagePath=server.mappath(gruppo & "_GENERALE_HIT.gif")
			'Salviamo l'immagine
			ChartObj.ExportPicture ImagePath,"gif", 600, 300
			set oChart=nothing

			response.write "[img]../images/transp.gif[/img]"

			%>

			<script> 
			<%="document.getElementById('HIT').src='" & gruppo & "_GENERALE_HIT.gif'"%>
			caric.style.display = 'none'; 
			</script>
			
			

 :ciauz:

[Baol74]

i grafici li puoi fare in html generandoli con script lato server, gerda lo script di weppos : http://www.weppos.com/stats/stats_hourly.asp.
Esistono script gratuiti.

L'altra posiibilità è generare delle gif senza installare componenti con aspcanvas : http://members.optusnet.com.au/~mrjolly/

Ciao

[vpoppa]

Sto cercando di realizzare un grafico ed ho utilizzato lo script segnalato nel forum, ma non riesco a realizzare un grafico con due curve che prendono i dati da un DB ACCESS.
Ti scrivo il codice in cui cerco di fare questa operazione:

....
grafico=false
if not Mostra_BUDGET_SE.eof then
grafico=true
for i = 1 to Mostra_BUDGET_SE.RecordCount
categorie(i) = Mostra_BUDGET_SE("ANNO")
valori(i) = Mostra_BUDGET_SE("SommaDiIMP_PROG")
Mostra_BUDGET_SE.MoveNext
next
set serie1 = chart.seriesCollection.add
serie1.SetData chConstants.chDimCategories, chConstants.chDataLiteral, categorie
serie1.SetData chConstants.chDimValues, chConstants.chDataLiteral, valori

Mostra_BUDGET_SE.MoveFirst
for i = 1 to Mostra_BUDGET_SE.RecordCount
categorie(i) = Mostra_BUDGET_SE("ANNO")
valori(i) = Mostra_BUDGET_SE("SommaDiIMP_ASS")
Mostra_BUDGET_SE.MoveNext
next
set serie1 = chart.seriesCollection.add
serie1.SetData chConstants.chDimCategories, chConstants.chDataLiteral, categorie
serie1.SetData chConstants.chDimValues, chConstants.chDataLiteral, valori
end if
....

I dati che vengono scritti in categorie e valori sono giusti, ma è giusto il grafico relativo solo alla prima curva (codice in grassetto).

Aiutatemi.

Vincenzo

[pieroseko]

come faccio a far visualizzare il valore sopra la barra ?