'CDONTS.Newmail' ?

[FICUZ]

tentando di inviare un'email ricevo questo errore, da cosa dipende ?
Il componente ActiveX non può creare l'oggetto: 'CDONTS.Newmail'

grazie

[fraude]

su che versione di windows server lavori?
potresti essere già sul 2003 che non supporta più CDONTS ma CDOSYS...

[FICUZ]

xp pro con iis

[fraude]

Fai partire questo script e fammi sapere cosa ti restituisce:

<%

	
	Dim comList(1)
	
	comList(0) = Array( "CDOSYS", "CDO.Message" )
	comList(1) = Array( "CDONTS", "CDONTS.NewMail" )

Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=3 cellspacing=3 border=0 align=center width=300>" & vbNewLine
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=200><font class=norm>" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=right width=20><font class=norm>[</font></td>"
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<td align=center><font face=tahoma size=2 color=blue>Available</font></td>"
				Avail = Avail + 1 
			Else
				strTxt = strTxt & "<td align=center><font class=norm>Unavailable</font></td>"
			End If
			strTxt = strTxt & "<td align=left width=20><font class=norm>]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font class=norm><font color=blue>" & Avail & "</font> of "
		strTxt = strTxt & UBound( comList ) + 1 & " supported components are available.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

[FICUZ]

CDOSYS [ Available ]
CDONTS [ Unavailable ]
1 of 2 supported components are available.

[fraude]

Originariamente inviato da FICUZ
CDOSYS [ Available ]
CDONTS [ Unavailable ]
1 of 2 supported components are available.

"Indi per cui" il componente che devi utilizzare per inviare le email non è CDONTS ma CDOSYS...
fai una ricerca sul forum con la aprola CDOSYS ci sono decine di esempi...

buonanotte...

[FICUZ]

ho caricato la pagina sul server e ho ricevuto error 500 senza ulteriori informazioni ma in locale cdonts non viene creato. mi chiedo una cosa: sulla stessa macchina ho un altro sito e su questo cdonts mi funziona . Ora come mai per questo no ?

[fraude]

Disabilita gli errori HTTP brevi dal menu strumenti --> opzioni internet --> avanzate di IE