Calcolare differenza tra data ed orario

[Mizushi]

Vorrei calcolare con ASP la differenza di data e di orario tra Milano e l'America centrale (-6 ore)ed ho scritto così:

<% 

sessionLCID = 1040 

dataMilano = date()
oraMilano = time()

dataAmericaCentrale = DateAdd("h",-6,oraRoma)

response.write dataMilano&" - "&oraMilano&"
"
response.write dataAmericaCentrale&"
"

%>

Per l'orario va bene, ma per la data? Cioè se in America centrale sono le 23 della sera ed a Milano le 5 del mattino lo script dovrebbe restituirmi:

A Milano sono: 02/10/2005 Ore 05:00
In America centrale sono: 01/10/2005 Ore 23:00

[nippotricco]

prova così:

dataMilano = Now()

dataAmericaCentrale = DateAdd("h", -6, dataMilano)
response.write dataMilano & "
"
response.write dataAmericaCentrale

[Mizushi]

OK grazie ma se volessi questo:

Sab 01 Ott 2005 22.14.58

invece di:

01/10/2005 22.14.58

Come devo modificare il codice?

[longline]

Una cosa è il valore dela data, altro è il formato di visualizzazione. Per ottenere ciò che vuoi, devi utilizzare funzioni tipo WeekDayName, MonthName, ecc...

Qui puoi trovare l'elenco di tutte le funzioni che possono esserti utile. Nota che i nomi di mesi e giorni possono essere visualizzati in inglese.

[Mizushi]

non ho capito cosa devo fare... se ho già una data nel formato

01/10/2005 22.14.58

come la trasformo in

Sab 01 Ott 2005 22.14.58

Il codice è questo:

<%
session.lcid=1040

dataMilano = Now()
response.write dataMilano & "
"

dataAmericaCentrale = DateAdd("h", -7, DataMilano)
response.write dataAmericaCentrale & "
"

%>

[longline]

Function FormattaDataComePiaceAMe(ByVal DatData)
  Dim strData
  strData = ""
  ' nome giorno
  strData = strData & WeekdayName(Weekday(DatData),true)
  ' numero giorno
  strData = strData & " " & Right("0" & Day(datData), 2)
  ' nome mese
  strData = strData & " " & MonthName(Month(datData),true)
  ' anno
  strData = strData & " " & Year(datData)
  ' ore e minuti
  strData = strData & " " & FormatDateTime(datData, 4)
  ' secondi
  strData = strData & " " & Second(datData)
  ' prepara la stringa finale
  FormattaDataComePiaceAMe = strData
End Function

L'ho scritta senza provarla...

[Mizushi]

Function FormattaDataComePiaceAMe(ByVal DatData)
  Dim strData
  strData = ""
  ' nome giorno
  strData = strData & WeekdayName(Weekday(DatData),true)
  ' numero giorno
  strData = strData & " " & Right("0" & Day(datData), 2)
  ' nome mese
  strData = strData & " " & MonthName(Month(datData),true)
  ' anno
  strData = strData & " " & Year(datData)
  ' ore e minuti
  strData = strData & " " & FormatDateTime(datData, 4)
  ' secondi
  strData = strData & " " & Second(datData)
  ' prepara la stringa finale
  FormattaDataComePiaceAMe = strData
End Function

dataOggi = FormattaDataComePiaceAMe(Now())
response.write dataOggi & "
"

dataAmericaCentrale = DateAdd("h", -7, DataOggi)
response.write dataAmericaCentrale & "
"

Restituisce:

sab 01 ott 2005 23.22 48
Microsoft VBScript runtime error '800a000d'

Type mismatch: '[string: "sab 01 ott 2005 23.2"]'

/default.asp, line 26

[longline]

Per forza, la mia funzione traduce una data in una stringa e per questo motivo non puoi dare il suo risultato in pasto ad una funzione che operi con le date.

Devi usare la funzione solamente quando vuoi visualizzare la data.

dataOggi = Now()
response.write FormattaDataComePiaceAMe(dataOggi) & "
"

dataAmericaCentrale = DateAdd("h", -7, DataOggi)
response.write FormattaDataComePiaceAMe(dataAmericaCentrale) & "
"

[Mizushi]

Grazie, gentilissimo... adesso ho capito...

Una "pignoleria": perchè tra i minuti ed i secondi non ci sono i due ounti che separano anche le ore dai minuti?:

Sab 01 Ott 2005 16:49 18

[longline]

Originariamente inviato da Mizushi
Grazie, gentilissimo... adesso ho capito...

Una "pignoleria": perchè tra i minuti ed i secondi non ci sono i due ounti che separano anche le ore dai minuti?:

Sab 01 Ott 2005 16:49 18

Perchè me li sono dimenticati (evidenziati in rosso)

Function FormattaDataComePiaceAMe(ByVal DatData)
  Dim strData
  strData = ""
  ' nome giorno
  strData = strData & WeekdayName(Weekday(DatData),true)
  ' numero giorno
  strData = strData & " " & Right("0" & Day(datData), 2)
  ' nome mese
  strData = strData & " " & MonthName(Month(datData),true)
  ' anno
  strData = strData & " " & Year(datData)
  ' ore e minuti
  strData = strData & " " & FormatDateTime(datData, 4)
  ' secondi
  strData = strData & ":" & Second(datData)
  ' prepara la stringa finale
  FormattaDataComePiaceAMe = strData
End Function