Tradurre da JScript a VBScript

[ubbicom]

Ciao.

Dovrei tradurre il seguente script da JScript in VBScript, potete aiutarmi ?

<%@ LANGUAGE = JScript %>
<%
var nickname = String(Request.Form("nickname"));
if (nickname!="undefined" && nickname!="") {
  if (nickname.indexOf("@")!=-1 || nickname.indexOf("$")!=-1) {
    Response.Write("ERRORE! NICKNAME NON VALIDO (ESCLUDERE @ E $)");
    Response.End;
  }
  Session("nickname") = nickname;
  Response.Redirect("chat.asp");
}
%>

<% 
// Controllo l'operazione di login
if (Session("nickname")==null) Response.End;
// Inizializzo l'Application nel caso essa non dovesse risultare inizializzata
if (Application("messaggi")==null) Application("messaggi") = "";
// Leggo l'Application
var messaggi = Application("messaggi");
// Divido le frasi
var frase = messaggi.split("$");
%>


<%
for (i=0;i<frase.length;i++) {
  aux = frase[i].split("@");
  if (aux.length>2) {
    Response.Write("<font size='1'>" + aux[0] + "</font> ");
    Response.Write("<font color='blue'>" + aux[1] + "</font> - ");
    Response.Write(aux[2] + "
");
  }
}
%>


<% 
if (Session("nickname")==null) Response.End;
if (Application("messaggi")==null) Application("messaggi") = "";

function replace(str1,str2,str3) {
  // Funzione di utilità
  while (str1.indexOf(str2)!=-1) str1 = str1.replace(str2,str3);
  return str1;
}

// Leggo autore e testo
var nickname = String(Session("nickname"));
var testo = String(Request.Form("testo"));

// Inserisco la nuova frase
if (testo!="undefined" && testo!="") {
  testo = replace(testo,"@","&#64;");
  testo = replace(testo,"$","&#36;");
  d = new Date();
  orario = "" + d.getHours() + ":" + d.getMinutes();
  Application.Lock();
  messaggi = Application("messaggi");
  nuova = orario + "@" + nickname + "@" + testo;
  var frase = messaggi.split("$");
  for (i=0;i<frase.length && i<19;i++)
    nuova += "$" + frase[i];
  Application("messaggi") = nuova;
  Application.UnLock();
}
%>

Grazie !

[willybit]

Ciao ubbicom,

dovrebbe essere così

<%@ LANGUAGE = VBScript %>
<%
nickname = Request.Form("nickname")
if nickname<>"" then
  if InStr(nickname,"@")>0 or InStr(nickname,"$")>0 then
    Response.Write "ERRORE! NICKNAME NON VALIDO (ESCLUDERE @ E $)"
    Response.End
  end if
  Session("nickname") = nickname
  Response.Redirect "chat.asp"
end if
%>

<% 
' Controllo l'operazione di login
if Session("nickname")="" then Response.End
' Inizializzo l'Application nel caso essa non dovesse risultare inizializzata
'QUESTO NON SERVE
'if Application("messaggi")="" then Application("messaggi") = ""
' Leggo l'Application
messaggi = Application("messaggi")
'Divido le frasi
frase = Split(messaggi,"$")
%>


<%
for i=0 to UBound(frase)
  aux = Split(frase(i),"@")
  if (UBound(aux)>2) then
    Response.Write "<font size='1'>" & aux(0) & "</font> "
    Response.Write "<font color='blue'>" & aux(1) & "</font> - "
    Response.Write aux(2) & "
"
  end if
next
%>


<% 
if Session("nickname")="" then Response.End
'QUESTO NON SERVE
'if Application("messaggi")="") then Application("messaggi") = ""

' Leggo autore e testo
nickname = Session("nickname")
testo = Request.Form("testo")

' Inserisco la nuova frase
if testo<>"" then
  testo = Replace(testo,"@","&#64;")
  testo = Replace(testo,"$","&#36;")
  d = Date
  orario = Hour(d) & ":" & Minute(d)
  Application.Lock
  messaggi = Application("messaggi")
  nuova = orario & "@" & nickname & "@" & testo
  frase = Split(messaggi,"$")
  for i=0 to UBound(frase)
    nuova = nuova & "$" & frase(i)
  next
  Application("messaggi") = nuova
  Application.UnLock
end if
%>

[ubbicom]

Ti ringrazio Willy, ma questa parte non dà errori ma non lo script non funziona più come dovrebbe :

<% 
' Controllo l'operazione di login
if Session("nickname")="" then Response.End
' Inizializzo l'Application nel caso essa non dovesse risultare inizializzata
'QUESTO NON SERVE
'if Application("messaggi")="" then Application("messaggi") = ""
' Leggo l'Application
messaggi = Application("messaggi")
'Divido le frasi
frase = Split(messaggi,"$")
%>


<%
for i=0 to UBound(frase)
  aux = Split(frase(i),"@")
  if (UBound(aux)>2) then
    Response.Write "<font size='1'>" & aux(0) & "</font> "
    Response.Write "<font color='blue'>" & aux(1) & "</font> - "
    Response.Write aux(2) & "
"
  end if
next
%>

è una semplice chat scritta in JS ma che per motivi di opportunità devo tradurre in VB; se vuoi ti mando lo zippato che pesa 144 kb.

Grazie!

[ubbicom]

OK adesso è tutto a posto... solo una cosa... perchè questo parte del codice:

'// Inserisco la nuova frase
if testo<>"" then
  testo = replace(testo,"@","&#64;")
  testo = replace(testo,"$","&#36;")
  d = Date
  orario = Hour(d) & ":" & Minute(d)
  Application.Lock
  messaggi = Application("messaggi")
  nuova = orario & "@" & nickname & "@" & testo
  frase = Split(messaggi,"$")
  for i=0 to UBound(frase)
	if i<19 then nuova = nuova & "$" & frase(i)
  next
  Application("messaggi") = nuova
  Application.UnLock
end if

Invece di stampare:

15:30 dario - ciao!

stampa :

0:0 dario - ciao !

Come mai?

[willybit]

azz è vero ... al posto di Date usa Now per avere anche ora e minuti

d = Now
orario = Hour(d) & ":" & Minute(d)

[ubbicom]

OK, ma adesso invece di :

16:03 sergio - ciao!

stampa:

16:3 sergio - ciao!

[willybit]

d = Now
orario = FormatDateTime(d,4)

[ubbicom]

Originariamente inviato da willybit

d = Now
orario = FormatDateTime(d,4)

Grazie ! a buon rendere !