estrapolare da .txt testo per controllo

[Ramsesdea]

Ciao a tutti ho la seguente necessità:

Ho un file di log.txt di questo genere


Group: ABC-rg server1 Online
Group: ABC-rg server4 Offline
Group: ABC-rg server2 Offline
Group: ABC-rg server3 Offline

Group: DEF-rg server1 Offline
Group: DEF-rg server4 Online
Group: DEF-rg server2 Offline
Group: DEF-rg server3 Offline



Dove il gruppo ABC per funzionare correttamente deve essere Online sul server1 mentre il gruppo DEF per funzionare deve essere Online su server 4


Da questo file di testo come posso fare un controllo automatico che mi prende il rigo Group: ABC-rg server1 e mi controlla se è Online senza che lo devo fare io ogni volta manualmente?

Si può fare con un bat?

Grazie a tutti

[Ramsesdea]

Ragazzi nessuno sa aiutarmi con questo quesito?

Ciao e grazie

[Samuele_70]

Originariamente inviato da Ramsesdea
[cut]

Da questo file di testo come posso fare un controllo automatico che mi prende il rigo Group: ABC-rg server1 e mi controlla se è Online senza che lo devo fare io ogni volta manualmente?

Si può fare con un bat?

Grazie a tutti

Cosa dovrebbe restituire questo bat ? Una volta effettuato il controllo intendo.
Vorresti semplicemente lanciare lo script, di tanto in tanto e leggerne il risultato ?

[Ramsesdea]

Ciao Samuele.

Il controllo già viene fatto se si lancia il comando scstat su un server SunCluster.

Il file che produce lo esporto in un .txt e il risultato è quello che ho messo prima

Group: ABC-rg server1 Online
Group: ABC-rg server4 Offline
Group: ABC-rg server2 Offline
Group: ABC-rg server3 Offline

Group: DEF-rg server1 Offline
Group: DEF-rg server4 Online
Group: DEF-rg server2 Offline
Group: DEF-rg server3 Offline



Il fatto è che non sono solo queste 4 righe da controllare ma sono un bel pò di più e farlo manualmente tutti i giorni impiega un bel pò di tempo.

Avrei la necessità di far effettuare in automatico il controllo,

esempio : se Group: ABC-rg server1 Online

allora lo stato è OK

altrimenti se per esempio Group: ABC-rg server4 Online

allora c'e' un problema.


Ciao e grazie ancora

[Samuele_70]

Prova questo 'simpatico' script (per Windows XP)
Copia e incolla in un file di testo e salvalo con estenzione .bat nella cartella
dove si trova il file di log.

@ECHO OFF
COLOR a0
REM Controllo su file log by Samuele_70 2006 ©
REM Windows XP

REM Nome del file di log
SET logFile="log.txt"

REM Imposto i dati del primo gruppo
SET gruppoNome1="ABC-rg"
SET serverCorretto1="server1"
SET messaggio1="Online"

REM Imposto i dati del secondo gruppo
SET gruppoNome2="DEF-rg"
SET serverCorretto2="server4"
SET messaggio2="Online"

REM Inizio elaborazioni
SET gruppo1=il gruppo %gruppoNome1% non e' connesso a nessun server !
SET gruppo2=il gruppo %gruppoNome2% non e' connesso a nessun server !
@FOR /F "usebackq tokens=2,3,4" %%a IN (%logFile%) DO (
	IF ["%%c"]==[%messaggio1%] (
		IF ["%%a"]==[%gruppoNome1%] (
				SET gruppo1=OK : Il gruppo "%%a" e' connesso al "%%b"
			IF NOT ["%%b"]==[%serverCorretto1%] (
				COLOR c0
				SET gruppo1=ATTENZIONE !: Il gruppo "%%a" e' connesso al "%%b" invece di %serverCorretto1%
			)
		)
	)
	IF ["%%c"]==[%messaggio2%] (
		IF ["%%a"]==[%gruppoNome2%] (
				SET gruppo2=OK : Il gruppo "%%a" e' connesso al "%%b"
			IF NOT ["%%b"]==[%serverCorretto2%] (
				COLOR c0
				SET gruppo2=ATTENZIONE !: Il gruppo "%%a" e' connesso al "%%b" invece di %serverCorretto2%
			)
		)
	)
)
ECHO.
ECHO                    Controllo connessioni by Samuele_70 2006 ©
ECHO.
ECHO.
ECHO %gruppo1%
ECHO %gruppo2%
ECHO.
ECHO.
PAUSE

[Ramsesdea]

Sei un mostro.....

Anche la schermata che cambia colore quando c'e' l'errore...


L'ho provato e sembra andare


Ora però lo proverò con il file completo....

Sicuramente è ok non sòcome ringraziarti

[Samuele_70]

Originariamente inviato da Ramsesdea



Sei un mostro.....

Anche la schermata che cambia colore quando c'e' l'errore...


L'ho provato e sembra andare

Ora però lo proverò con il file completo....

Sicuramente è ok non sòcome ringraziarti

Pizza & birra?
Fammi sapere se è ok.

[Ramsesdea]

Pizza e birra .... aggiudicato....

Sembra funzionare alla grande anche con il file completo.

Solo una cosa mi serve sapere però....

Mi spiegheresti cortesemente il comando

@FOR /F "usebackq tokens=2,3,4" %%a IN (%logFile%) DO (


Nello specifico mi servirebbe sapere cosa vuol dire "usebackq tokens=2,3,4"


Il file completo ha 22 gruppi e volevo sapere se influisce sul rigo "usebackq tokens=2,3,4"

(sinceramente non credo che influisca visto che con tutte le conbinazioni di Offline e Online funziona alla grande.)

Cmq grazie ancora tanto, è eccezionale questo .bat

[Ramsesdea]

Approposito ma si trovano in giro esempi simili dove si possono prendere spunti?

[OZZY IS BACK...]

Originariamente inviato da Ramsesdea
Approposito ma si trovano in giro esempi simili dove si possono prendere spunti?

sarei interessato anche io!