invio email

**thitan** · 17-05-2006, 10:50

ciao, dovendo fare un piacere a un amico mi ritrovo con il codice

Codice PHP:


<%

' invio per posta elettronica del modulo di contatto

dim sBody    ' stringa contenente il body della mail

dim sSubject    ' stringa contenente il subject della mail

dim sSender    ' stringa contenente il destinatario della mail

dim sReceiver    ' stringa contenente il ricevente del messaggio

sSubject = "Messaggio dal modulo di contatto web"

'sReceiver = "marcoma@mediap.net"

sReceiver = "info@motoclassiche.it"

sSender = Request.Form ("email")

sBody = ""

sBody = sBody & "********************************************************************************" & vbCrLf

sBody = sBody & "Nome:" & Request.Form ("nome") & vbCrLf

sBody = sBody & "Telefono:" & Request.Form ("telefono") & vbCrLf

sBody = sBody & "Fax:" & Request.Form ("fax") & vbCrLf

sBody = sBody & "Home Page:" & Request.Form ("URL") & vbCrLf

sBody = sBody & "E-Mail:" & Request.Form ("email") & vbCrLf & vbCrLf

sBody = sBody & "Messaggio:" & vbCrLf  & vbCrLf

sBody = sBody & Request.Form ("messaggio")

'SendMail sSender,sReceiver,sSubject,sBody,"","","","",""







Dim miaMail

Set miaMail = CreateObject("CDONTS.NewMail")



miaMail.From = "info@motoclassiche.it"

miaMail.To = sSender

miaMail.Subject = sSubject

miaMail.BodyFormat = 0

miaMail.MailFormat = 0

miaMail.Importance = 0



miaMail.Body = sBody

miaMail.Send



Set miaMail = Nothing 



%>

ma mi stampa l'errore

Errore di run-time di Microsoft VBScript error '800a0046'

Autorizzazione negata

/risposta_modulo.asp, line 38

la riga 38 è quella con il miaMail.Send.

dovè l'errore?

**maximum** · 17-05-2006, 11:50

Sicuro che il tuo spazio supporti CDONTS?
Verifica contattando l'hoster.

**thitan** · 17-05-2006, 12:45

bho non saprei, lo spazio non l'ho preso io...
come posso inviare un'email nel modo più semplice possibile?
conosco bene il php ma l'asp mai usato, stò cercando di aiutare un amico

**maximum** · 17-05-2006, 12:50

Devi prima vedere quale componente è attivo sul server su cui girano le tue pagine.
CDONTS ti restituisce quell'errore.....potresti provare CDOSYS, ma meglio sempre avere delle certezze.

**thitan** · 17-05-2006, 12:51

Originariamente inviato da maximum
Devi prima vedere quale componente è attivo sul server su cui girano le tue pagine.
CDONTS ti restituisce quell'errore.....potresti provare CDOSYS, ma meglio sempre avere delle certezze.

e come faccio a verificare? devo per forza contattare quelli dell'hosting o c'è uno script di verifica?

**Peter_Pan** · 17-05-2006, 16:52

codice:

<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
<TITLE></TITLE>
</HEAD>
<BODY>
<%
	' Creiamo la lista dei componenti da controllare !
	' Potete aggiungere tutti quelli che volete nel formato
	' ListaCOM(x) = Array("nome_componente","nome_componente.chiamata_componente")
	Dim ListaCOM(47)
	ListaCOM(0) = Array( "AB Mailer","ABMailer.Mailman" )
	ListaCOM(1) = Array( "ABC Upload","ABCUpload4.XForm" )
	ListaCOM(2) = Array( "ActiveFile","ActiveFile.Post" )
	ListaCOM(3) = Array( "ActiveX Data Object","ADODB.Connection" )
	ListaCOM(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
	ListaCOM(5) = Array( "ASP HTTP","AspHTTP.Conn" )
	ListaCOM(6) = Array( "ASP Image","AspImage.Image" )
	ListaCOM(7) = Array( "ASP Mail","SMTPsvg.Mailer" )
	ListaCOM(8) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
	ListaCOM(9) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
	ListaCOM(10) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
	ListaCOM(11) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
	ListaCOM(12) = Array( "ASP Tear","SOFTWING.ASPtear" )
	ListaCOM(13) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
	ListaCOM(14) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
	ListaCOM(15) = Array( "ASPSoft NT Object","ASPSoft.NT" )
	ListaCOM(16) = Array( "ASPSoft Upload","ASPSoft.Upload" )
	ListaCOM(17) = Array( "CDO NTS","CDONTS.NewMail" )
	ListaCOM(18) = Array( "Chestysoft Image","csImageFile.Manage" )
	ListaCOM(19) = Array( "Chestysoft Upload","csASPUpload.Process" )
	ListaCOM(20) = Array( "Dimac JMail","JMail.Message" )
	ListaCOM(21) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
	ListaCOM(22) = Array( "Dundas Mailer","Dundas.Mailer" )
	ListaCOM(23) = Array( "Dundas Upload","Dundas.Upload.2" )
	ListaCOM(24) = Array( "Dynu Encrypt","Dynu.Encrypt" )
	ListaCOM(25) = Array( "Dynu HTTP","Dynu.HTTP" )
	ListaCOM(26) = Array( "Dynu Mail","Dynu.Email" )
	ListaCOM(27) = Array( "Dynu Upload","Dynu.Upload" )
	ListaCOM(28) = Array( "Dynu WhoIs","Dynu.Whois" )
	ListaCOM(29) = Array( "Easy Mail","EasyMail.SMTP.5" )
	ListaCOM(30) = Array( "File System Object","Scripting.FileSystemObject" )
	ListaCOM(31) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
	ListaCOM(32) = Array( "Last Mod","LastMod.FileObj" )
	ListaCOM(33) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
	ListaCOM(34) = Array( "Persits ASP JPEG","Persits.Jpeg" )
	ListaCOM(35) = Array( "Persits ASPEmail","Persits.MailSender" )
	ListaCOM(36) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
	ListaCOM(37) = Array( "Persits File Upload","Persits.Upload.1" )
	ListaCOM(38) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
	ListaCOM(39) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
	ListaCOM(40) = Array( "Image Size", "ImgSize.Check" )
	ListaCOM(41) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
	ListaCOM(42) = Array( "Microsoft OWC9 Chart", "OWC.Chart.9" )
	ListaCOM(43) = Array( "Microsoft CDONTS", "CDONTS.NewMail" )
	ListaCOM(44) = Array( "Microsoft XML DOM", "Microsoft.XLMDOM" )
	ListaCOM(45) = Array( "Microsoft MSXML DOM", "MSXML.DOMDocument" )
	ListaCOM(46) = Array( "Microsoft OWC10 Chart", "OWC10.ChartSpace" )
	ListaCOM(47) = Array( "CDOSYS", "CDO.message" )
	
	
	
	
	' Creiamo la funzione per vedere quali di questi sono attivi

	Function attiva( comIdentity )
		On Error Resume Next
		attiva = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )

		If Err = 0 Then attiva = True
			Set xTestObj = Nothing
		Err = 0
	End Function

	' Creiamo la funzione per controllare i componenti e per stampare i risultati
	Public Function controllaCOM()
	disponibile = 0
	strTxt = "<table cellpadding=3 cellspacing=3 border=0 align=center width=400>" & vbNewLine
	For indice = LBound( ListaCOM ) To UBound( ListaCOM )
	Provider = indice
	strTxt = strTxt & vbTab & "<tr><td width=200><font face=Verdana size=2>" & ListaCOM(indice)(0) & "</font></td>"
	strTxt = strTxt & "<td align=right width=20><font face=Verdana size=2>[</font></td>"

	If attiva( ListaCOM(indice)(1) ) Then
	strTxt = strTxt & "<td align=center><font face=Verdana size=2 color=blue>Disponibile</font></td>"
	disponibile = disponibile + 1
	Else
	strTxt = strTxt & "<td align=center><font face=Verdana size=2>No</font></td>"
	End If
	strTxt = strTxt & "<td align=left width=20><font face=Verdana size=2 target=_blank>]</font></td></tr>" & vbNewLine
	Next
	strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><center><font face=Verdana size=2><font color=blue>" & disponibile & "</font> dei "
	strTxt = strTxt & UBound( ListaCOM ) + 1 & " componenti della lista sono supportati.</font></center></td></tr>" & vbNewLine
	controllaCOM = strTxt & "</table>" & vbNewLine
	End Function

	' E adesso vediamo di visualizzare il tutto
	Response.Write( controllaCOM() )
%>

</BODY>
</HTML>

Se copi tutto in una pagina con estensione .asp, la metti sul server e la richiami da esplorer, ti dirà tra l'elenco presente nell'array quali componenti sono attivi sul server.
Nell'elenco c'è sia CDONTS che CDOSYS che servono entrmbi per inviare mail.

Discussione: invio email

Strumenti discussione

Ricerca discussione

Visualizza

invio email

Permessi di invio